feat(pops.hive): add homeConfiguration

src/hive/collectors/homeConfigurations.nix

@@ -0,0 +1,54 @@
+# SPDX-FileCopyrightText: 2024 The divnix/hive Authors
+#
+# SPDX-License-Identifier: Unlicense
+
+{
+  lib,
+  root,
+  super,
+}:
+let
+  inherit (lib) pipe;
+  l = lib // builtins;
+  inherit (root.hive) checks transformers;
+
+  # Error reporting
+  showAssertions =
+    let
+      collectFailed =
+        cfg: l.map (x: x.message) (l.filter (x: !x.assertion) cfg.assertions);
+      showWarnings =
+        res:
+        let
+          f = w: x: l.trace "warning: ${w}" x;
+        in
+        l.fold f res res.config.warnings;
+    in
+    evaled:
+    showWarnings (
+      let
+        failed = collectFailed evaled.config;
+        failedStr = l.concatStringsSep "\n" (map (x: "- ${x}") failed);
+      in
+      if failed == [ ] then evaled else throw "\nFailed assertions:\n${failedStr}"
+    );
+
+  hmCliSchema =
+    evaled:
+    let
+      asserted = showAssertions evaled;
+    in
+    {
+      # __schema = "v0";
+      inherit (asserted) options config;
+      inherit (asserted.config.home) activationPackage;
+      newsDisplay = evaled.config.news.display;
+      newsEntries = l.sort (a: b: a.time > b.time) (
+        l.filter (a: a.condition) evaled.config.news.entries
+      );
+    };
+in
+super.walk transformers.homeConfiguration [
+  (config: config.bee._evaled)
+  hmCliSchema
+]

src/hive/transformers/homeConfiguration.nix

@@ -0,0 +1,50 @@
+# SPDX-FileCopyrightText: 2024 The divnix/hive Authors
+#
+# SPDX-License-Identifier: Unlicense
+
+{ lib, root }:
+{
+  evaled,
+  locatedConfig,
+  inputs ? { },
+}:
+let
+  inherit (root.hive) beeModule;
+
+  l = lib // builtins;
+
+  hmLib = import (evaled.config.bee.home + /modules/lib/stdlib-extended.nix) lib;
+
+  hmModules = import (evaled.config.bee.home + /modules/modules.nix) {
+    inherit (evaled.config.bee) pkgs;
+    lib = hmLib;
+    check = true;
+    # we switch off the nixpkgs module, package instantiation needs
+    # to happen on the `std` layer
+    useNixpkgsModule = false;
+  };
+  eval =
+    extra:
+    lib.evalModules {
+      specialArgs = {
+        modulesPath = l.toString (evaled.config.bee.home + /modules);
+      };
+      modules = [
+        beeModule
+        locatedConfig
+        extra
+      ] ++ hmModules;
+    };
+  bee = evaled.config.bee // {
+    _evaled = eval { config._module.check = true; };
+    _unchecked = eval { config._module.check = false; };
+  };
+in
+{
+  inherit bee;
+  # complete module set, can be lib.evalModuled as-is
+  imports = [
+    beeModule
+    locatedConfig
+  ] ++ hmModules;
+}

src/ops/readEnv.nix

@@ -0,0 +1,28 @@
+# copyright: @domenkozar https://github.com/cachix/devenv/issues/516#issue-1652139691
+
+{ lib }:
+let
+  parseLine =
+    line:
+    let
+      parts = builtins.match "(.+) *= *(.+)" line;
+    in
+    if (!builtins.isNull parts) && (builtins.length parts) == 2 then
+      {
+        name = builtins.elemAt parts 0;
+        value = builtins.elemAt parts 1;
+      }
+    else
+      null;
+
+  parseEnvFile =
+    content:
+    builtins.listToAttrs (
+      lib.filter (x: !builtins.isNull x) (
+        map parseLine (lib.splitString "\n" content)
+      )
+    );
+
+  envContent = file: builtins.readFile file;
+in
+parseEnvFile envContent

src/pops/hive.nix

@@ -36,6 +36,7 @@ in
     nixosConfigurationRenamer = "nixosConfiguration";
     darwinConfigurationRenamer = "darwinConfiguration";
     colmenaConfigurationRenamer = "colmenaConfiguration";
+    homeConfigurationRenamer = "homeConfiguration";
     exports = {
       hosts = { };
     };
@@ -72,6 +73,9 @@ in
       setNixosConfigurationsRenamer =
         renamer: extendPop final (_: _: { nixosConfigurationRenamer = renamer; });
 
+      setHomeConfigurationsRenamer =
+        renamer: extendPop final (_: _: { homeConfigurationRenamer = renamer; });
+
       setDarwinConfigurationsRenamer =
         renamer: extendPop final (_: _: { darwinConfigurationRenamer = renamer; });
 
@@ -85,6 +89,8 @@ in
         colmenaHive = root.hive.collectors.colmenaConfigurations final.colmenaConfigurationRenamer hostsArgs;
 
         nixosConfigurations = root.hive.collectors.nixosConfigurations final.nixosConfigurationRenamer hostsArgs;
+
+        homeConfigurations = root.hive.collectors.homeConfigurations final.homeConfigurationRenamer hostsArgs;
         # hosts = lib.omnibus.mkHosts {
         #   # hostsDir = projectRoot + "/units/nixos/hosts";
         #   hostsDir = ./.;

tests/hive/expr.nix

@@ -37,6 +37,12 @@ let
         bee.system = system;
         bee.pkgs = import nixpkgs { system = system; };
       };
+
+      homeConfiguration = {
+        bee.system = system;
+        bee.pkgs = import nixpkgs { system = system; };
+        bee.home = omnibus.flake.inputs.home-manager;
+      };
     };
   };
   hivePop =