dev-util/repolite: add latest upstream release

* this one has changelog support

Signed-off-by: Stephen L Arnold <nerdboy@gentoo.org>

dev-util/repolite/Manifest

@@ -1 +1,2 @@
 DIST repolite-0.6.1.gh.tar.gz 42589 BLAKE2B b18174a9ae984d4db64815205e8b91bea8e7b3ad028b406439597e6609a4d5340feb9285963d1236a14d3eb9725c19e0d219b71a2bf7501bc4961645d8594f80 SHA512 6cfdc9a2894deab6834fffdf4bbca9fc565cf7c322a1c9c0d3a2d43e17db614db30169f6d52c518a01032b62ebb8e34ee0e256e4bf2f15a9acf5a4f3ce2016a8
+DIST repolite-0.6.2.gh.tar.gz 43813 BLAKE2B a92ccf585b5b91a905d7293ff1d90a10e13d1928d22909bb667496c16469968702b5cbe1040ef2042afc916b51c9426f1f0e80746deedceefe38a69c1495916b SHA512 290f3ab3d177e98a63bcea6dc24e890c4a637aa498fde374dae9f4362c78df0ba38795d39ef24377611998e677b7158aa54dde18b664b5d766a395f338426fae

dev-util/repolite/repolite-0.6.2.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Manage a small-ish set of git repositories with YAML configs."
+HOMEPAGE="https://github.com/sarnold/repolite"
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/sarnold/repolite.git"
+	EGIT_BRANCH="master"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/sarnold/repolite/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc"
+RESTRICT="test"  # no tests :(
+
+RDEPEND="
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/munch[${PYTHON_USEDEP}]
+        dev-util/gitchangelog[${PYTHON_USEDEP}]
+	dev-vcs/git
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( README.rst )
+
+distutils_enable_sphinx \
+	docs/source \
+	dev-python/sphinx-rtd-theme \
+	dev-python/recommonmark \
+	dev-python/sphinxcontrib-apidoc
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	sed -i '/sphinx_git/d' "${S}"/setup.cfg "${S}"/docs/source/conf.py
+	default
+}
+
+pkg_postinst() {
+	optfeature "initialize repos with lfs files" dev-vcs/git-lfs
+}