forked from alapshin/nixos-config
-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
183 lines (160 loc) · 4.82 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
{
description = "A flake-based nixos config.";
inputs = {
nixos.url = "nixpkgs/nixos-unstable";
nixpkgs.url = "nixpkgs/master";
nur.url = "github:nix-community/nur";
disko.url = "github:nix-community/disko?ref=v1.3.0";
disko.inputs.nixpkgs.follows = "nixos";
sops-nix.url = "github:Mic92/sops-nix";
sops-nix.inputs.nixpkgs.follows = "nixos";
lanzaboote.url = "github:nix-community/lanzaboote";
lanzaboote.inputs.nixpkgs.follows = "nixos";
home-manager.url = "github:nix-community/home-manager/master";
home-manager.inputs.nixpkgs.follows = "nixos";
plasma-manager.url = "github:pjones/plasma-manager";
plasma-manager.inputs.nixpkgs.follows = "nixos";
plasma-manager.inputs.home-manager.follows = "home-manager";
subtitlecomposer.url = "github:kugland/nixpkgs/?ref=subtitlecomposer";
};
outputs =
inputs @ { self
, nixos
, nixpkgs
, nur
, disko
, sops-nix
, lanzaboote
, home-manager
, ...
}:
let
inherit (nixos) lib;
system = "x86_64-linux";
configDir = builtins.toString ./.;
secretDir = "${configDir}/secrets";
dotfileDir = "${configDir}/dotfiles";
nixpkgsConfig = {
allowUnfree = true;
android_sdk.accept_license = true;
permittedInsecurePackages = [ ];
};
mkPkgs =
{ pkgs
, extraOverlays ? [ nur.overlay ]
}:
import pkgs {
inherit system;
config = nixpkgsConfig;
overlays = (lib.attrValues self.overlays) ++ extraOverlays;
};
pkgs = mkPkgs { pkgs = nixos; };
homeManagerConfig = {
# Use global pkgs configured via nixpkgs.* options
home-manager.useGlobalPkgs = true;
# Install user packages to /etc/profiles instead.
# Necessary for nixos-rebuild build-vm to work.
home-manager.useUserPackages = true;
home-manager.extraSpecialArgs = {
inherit dotfileDir secretDir;
};
home-manager.sharedModules = [
sops-nix.homeManagerModules.sops
];
};
mkNixosConfiguration =
{ system ? "x86_64-linux"
, baseModules ? [
./configuration.nix
self.nixosModules.qbittorrent
disko.nixosModules.disko
sops-nix.nixosModules.sops
lanzaboote.nixosModules.lanzaboote
home-manager.nixosModules.home-manager homeManagerConfig
]
, hostModules ? [ ]
, userModules ? [ ]
, specialArgs ? { }
,
}:
nixos.lib.nixosSystem {
inherit system;
modules = baseModules ++ hostModules ++ userModules;
specialArgs = specialArgs // {
inherit inputs pkgs self dotfileDir;
};
};
in
{
# Custom packages and modifications, exported as overlays
overlays = import ./overlays { inherit inputs; };
# Custom packages acessible through 'nix build', 'nix shell', etc
# packages = import ./packages {inherit pkgs;};
devShells = {
${system} = {
android = pkgs.android-fhs-env.env;
};
};
formatter = {
${system} = pkgs.nixpkgs-fmt;
};
# Reusable nixos modules you might want to export
# These are usually stuff you would upstream into nixpkgs
nixosModules = import ./modules/nixos;
nixosConfigurations = {
carbon = mkNixosConfiguration {
hostModules = [
./hosts/common
./hosts/carbon
];
userModules = [
./users/alapshin
];
};
desktop = mkNixosConfiguration {
hostModules = [
./hosts/common
./hosts/desktop
];
userModules = [
./users/alapshin
];
};
altdesk = mkNixosConfiguration {
hostModules = [
./hosts/common
./hosts/altdesk
];
userModules = [
./users/alapshin
];
};
server = mkNixosConfiguration {
hostModules = [
./hosts/server
"${nixos}/nixos/modules/profiles/qemu-guest.nix"
];
specialArgs = { domainName = "alapshin.com"; };
};
};
# Stand-alone home-manager configuration for non NixOS machines
homeConfigurations =
let
username = "alapshin";
in
{
"${username}" = home-manager.lib.homeManagerConfiguration {
inherit pkgs;
modules = [ ./users/alapshin/home/home.nix ];
extraSpecialArgs = {
inherit username dotfileDir secretDir;
osConfig = {
networking = {
hostName = "workstation";
};
};
};
};
};
};
}