Is there support for var-file layering?

[az-z]

Hello,
is there support for var-file layering?
e.g.
proj
| - dev
| | - dev.tfvar
| | - stack#
| | | - stack#.tfvar
| .................
| - general
| | - general.tfvars
| - proj.tfvars

so that to deploy "general" stack: terraform --var-file=../proj.tfvar --var-file=general.tfvar
As you see, I use var files in a similar fashion "globals" are used in TM.

[i4ki]

Hi @az-z

There's no explicit support but you can achieve the same behavior using globals and terramate.config.run.env. Example below:

Let's say you have the tree below:

$ tree .
.
├── common.tfvars
├── others.tfvars
├── README.md
├── stack-a
│   └── terramate.tm.hcl
├── stack-b
│   ├── stack-b-1.tfvars
│   ├── stack-b-2.tfvars
│   └── terramate.tm.hcl
├── stack-c
│   ├── stack-c.tfvars
│   └── terramate.tm.hcl
└── terramate.tm.hcl

then in the /terramate.tm.hcl you add this configuration:

terramate {
  config {
    run {
      env {
        TF_CLI_ARGS = global.tf_cli_args
      }
    }
  }	
}

globals {
  hierarchy_parts = tm_split("/", terramate.stack.path.absolute)
  hierarchy_dirs = [for i in tm_range(0, tm_length(global.hierarchy_parts)) : "${terramate.stack.path.to_root}${tm_join("/", tm_slice(global.hierarchy_parts, 0, i+1))}"]
  tf_var_sets = [for dir in global.hierarchy_dirs : [for path in tm_fileset(dir, "*.tfvars") : "${dir}/${path}"]]
  tf_var_files = tm_flatten(global.tf_var_sets)
  tf_cli_args = tm_join(" ", [for f in global.tf_var_files : "-var-file ${f}"])
}

The code above will compute the set of --var-file for each stack having in consideration the hierarchy of .tfvars, in other words, each stack will have its own .tfvars plus all .tfvars from parent directories until project root set by an environment variable.
The env.TF_CLI_ARGS is documented here.

Then have a look in the run below (just printing the environment variable):

$ terramate --log-level=info run -- printenv TF_CLI_ARGS
2023-01-19T23:46:04Z INF running cmd="printenv TF_CLI_ARGS" stack=/stack-a
-var-file ../common.tfvars -var-file ../others.tfvars
2023-01-19T23:46:04Z INF running cmd="printenv TF_CLI_ARGS" stack=/stack-b
-var-file ../common.tfvars -var-file ../others.tfvars -var-file ../stack-b/stack-b-1.tfvars -var-file ../stack-b/stack-b-2.tfvars
2023-01-19T23:46:04Z INF running cmd="printenv TF_CLI_ARGS" stack=/stack-c
-var-file ../common.tfvars -var-file ../others.tfvars -var-file ../stack-c/stack-c.tfvars

Then, for any terraform command, this env var will be exported adding the extra cli args for you.
Run terramate experimental globals to inspect the globals generated so you can understand and make adjustments if needed.

Does it solve your problem?

We at Mineiros prefer to have the configuration as Terramate globals, so we have better control and reuse them across all stacks. We don't use TFVARs but generate the globals whenever needed, but using core Terramate features you should be able to come up with different strategies.