-
Notifications
You must be signed in to change notification settings - Fork 2
/
raycast1.fs
211 lines (174 loc) · 4.32 KB
/
raycast1.fs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
\ uses sprites 8-15
17 ficl-vocabulary raycast-voc
also raycast-voc definitions
0 DEFINE-SFX jump.wav
\ floats
VARIABLE posX
VARIABLE posY
VARIABLE dirX
VARIABLE dirY
VARIABLE planeX
VARIABLE planeY
\ int
VARIABLE column
\ floats
VARIABLE cameraX
VARIABLE rayDirX
VARIABLE rayDirY
\ ints
VARIABLE mapX
VARIABLE mapY
: calc-position-and-direction
column @ 2* S>F W S>F F/ 1e f- cameraX F!
cameraX F@ planeX F@ F* dirX F@ F+ rayDirX F!
cameraX F@ planeY F@ F* dirY F@ F+ rayDirY F!
posX F@ F>S mapX !
posY F@ F>S mapY !
;
\ floats
VARIABLE sideDistX
VARIABLE sideDistY
\ floats
VARIABLE deltaDistX
VARIABLE deltaDistY
VARIABLE perpWallDist
\ ints
VARIABLE stepX
VARIABLE stepY
\ ints
VARIABLE hit
VARIABLE side
: calc-step-and-sideDist
rayDirX F@ F0< IF
-1 stepX !
posX F@ mapX @ S>F F- deltaDistX F@ F* sideDistX F!
ELSE
1 stepX !
mapX @ S>F 1e F+ posX F@ F- deltaDistX F@ F* sideDistX F!
THEN
rayDirY F@ F0< IF
-1 stepY !
posY F@ mapY @ S>F F- deltaDistY F@ F* sideDistY F!
ELSE
1 stepY !
mapY @ S>F 1e F+ posY F@ F- deltaDistY F@ F* sideDistY F!
THEN
;
: perform-DDA
BEGIN
sideDistX F@ sideDistY F@ F< IF
deltaDistX F@ sideDistX F+!
stepX @ mapX +!
0 side !
ELSE
deltaDistY F@ sideDistY F+!
stepY @ mapY +!
1 side !
THEN
\ check if ray hits a wall
mapX @ mapY @ M@
UNTIL
;
\ Calculate distance projected on camera direction
\ (Euclidean distance will give fisheye effect!)
: calc-distance-projected
side @ IF
1 stepY @ - 2/ mapY @ + S>F posY F@ F- rayDirY F@ F/ perpWallDist F!
ELSE
1 stepX @ - 2/ mapX @ + S>F posX F@ F- rayDirX F@ F/ perpWallDist F!
THEN
;
\ ints
VARIABLE lineHeight
VARIABLE drawStart
VARIABLE drawEnd
: calc-lowest-highest
H S>F perpWallDist F@ F/ F>S lineHeight !
lineHeight @ NEGATE 2/ H 2/ + 0 MAX drawStart !
lineHeight @ 2/ H 2/ + H 1- MIN drawEnd !
;
\ ints
VARIABLE lineColor
: calc-color
mapX @ mapY @ M@ lineColor !
\ side @ IF lineColor @ 2/ lineColor ! THEN
;
: draw-line lineColor @ column @ drawStart @ column @ drawEnd @ line ;
: draw3d
W 0 DO
I column !
calc-position-and-direction
1e rayDirX F@ F/ FABS deltaDistX F!
1e rayDirY F@ F/ FABS deltaDistY F!
FALSE hit !
0 side !
calc-step-and-sideDist
perform-DDA
calc-distance-projected
calc-lowest-highest
calc-color
draw-line
LOOP
;
: <init>
s" default.spr" load-sprites
s" default.map" load-map
4e posX F!
4e posY F!
-1e dirX F!
0e dirY F!
0e planeX F!
0.66e planeY F!
;
: ?exit ( -- ) SCANCODE_Q pressed? IF retro-40 THEN ;
VARIABLE oldDirX
VARIABLE oldPlaneX
0.05e FCONSTANT moveSpeed
0.03e FCONSTANT rotSpeed
: move-forward
posX F@ dirX F@ moveSpeed F* F+ F>S posY F@ F>S M@ 0= IF
dirX F@ moveSpeed F* posX F+!
THEN
posX F@ F>S posY F@ dirY F@ moveSpeed F* F+ F>S M@ 0= IF
dirY F@ moveSpeed F* posY F+!
THEN
;
: move-backward
posX F@ dirX F@ moveSpeed F* F- F>S posY F@ F>S M@ 0= IF
dirX F@ moveSpeed F* FNEGATE posX F+!
THEN
posX F@ F>S posY F@ dirY F@ moveSpeed F* F- F>S M@ 0= IF
dirY F@ moveSpeed F* FNEGATE posY F+!
THEN
;
: turn-left
dirX F@ oldDirX F!
planeX F@ oldPlaneX F!
dirX F@ rotSpeed FCOS F* dirY F@ rotSpeed FSIN F* F- dirX F!
oldDirX F@ rotSpeed FSIN F* dirY F@ rotSpeed FCOS F* F+ dirY F!
planeX F@ rotSpeed FCOS F* planeY F@ rotSpeed FSIN F* F- planeX F!
oldPlaneX F@ rotSpeed FSIN F* planeY F@ rotSpeed FCOS F* F+ planeY F!
;
: turn-right
dirX F@ oldDirX F!
planeX F@ oldPlaneX F!
dirX F@ rotSpeed FNEGATE FCOS F* dirY F@ rotSpeed FNEGATE FSIN F* F- dirX F!
oldDirX F@ rotSpeed FNEGATE FSIN F* dirY F@ rotSpeed FNEGATE FCOS F* F+ dirY F!
planeX F@ rotSpeed FNEGATE FCOS F* planeY F@ rotSpeed FNEGATE FSIN F* F- planeX F!
oldPlaneX F@ rotSpeed FNEGATE FSIN F* planeY F@ rotSpeed FNEGATE FCOS F* F+ planeY F!
;
: ?move ( -- )
SCANCODE_W pressed? IF move-forward THEN
SCANCODE_S pressed? IF move-backward THEN
;
: ?turn ( -- )
SCANCODE_A pressed? IF turn-left THEN
SCANCODE_D pressed? IF turn-right THEN
;
: <update> ( -- ) ?move ?turn ?exit ;
: <draw> ( -- ) 0 cls draw3d ;
\ install the software
PREVIOUS DEFINITIONS
ALSO raycast-voc
INSTALL raycast
PREVIOUS