-
Notifications
You must be signed in to change notification settings - Fork 1
/
notepad++.JSS
108 lines (102 loc) · 2.93 KB
/
notepad++.JSS
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
; Scripts for Notepad++
; Written by Munawar Bijani
include "hjconst.jsh";
globals
string indentMSG;
Int Function announceTabs ()
var
string msg,
int currentCharacter,
int numTabs,
int numSpaces;
; First, we'll use the invisible cursor to save the location of the PC Cursor.
; This is because we move the PC Cursor in order to get the indent count.
invisibleCursor();
routeInvisibleToPc ();
PCCursor();
; Announcing the indent on a blank line is a waste.
if (StringIsBlank(getLine())) then
routePCToInvisible();
indentMsg = "";
return 1;
EndIf
JAWSHome();
currentCharacter = GetCharacterValue (getCharacter());
if (currentCharacter != 0 && currentCharacter != 9 && currentCharacter != 32) then
; Some editors position the cursor at the beginning of a line on the first press of home. This is the case with Notepad++
JAWSHome();
currentCharacter = getCharacterValue(getCharacter());
EndIf
while (currentCharacter == 0 || currentCharacter == 9 || currentCharacter == 32)
; JAWS sees tab characters as null characters, so we'll treat all nulls and character(9)'s as tabs, though character(9) might never occur.
if (currentCharacter == 0 || currentCharacter == 9) then
numTabs = numTabs + 1;
else
numSpaces = numSpaces + 1;
EndIf
nextCharacter();
currentCharacter = getCharacterValue(getCharacter());
EndWhile
if (numTabs > 0) then
msg = intToString(numTabs) + " tab";
if (numTabs > 1) then
msg = msg + "s";
EndIf
EndIf
if (numSpaces > 0) then
if (msg != "") then
msg = msg + " and ";
EndIf
msg = msg + intToString(numSpaces) + " space";
if (numSpaces > 1) then
msg = msg + "s";
endIf
EndIf
if (msg == "") then
msg = "No indent";
EndIf
if (msg != indentMSG) then
sayUsingVoice (VCTX_MESSAGE, msg, OT_STATUS);
indentMSG = msg;
EndIf
; Finally, restore the PC Cursor. We left the Invisible Cursor at the PC Cursor's previous position so we can simply route it back.
routePcToInvisible ();
return 1;
EndFunction
Script QuickSettings ()
var
int announceIndent;
PerformScript QuickSettings();
announceIndent = GetJCFOptionFromFile ("NonJCFOptions", "NotepadPPIndent");
if (announceIndent) then
SetJCFOption (OPT_INDICATE_INDENTATION, 0);
EndIf
EndScript
Int Function isInTextEditor ()
var
int cond;
cond = IsPCCursor () && GetJCFOptionFromFile ("NonJCFOptions", "NotepadPPIndent") && GetWindowClass (GetFocus()) == "Scintilla";
; Next, if we've turned on custom indent behavior, we'll turn off the JAWS default indent behavior for Notepad++ if it's on.
if (cond && GetJCFOption (OPT_INDICATE_INDENTATION)) then
SetJCFOption (OPT_INDICATE_INDENTATION, 0);
endIf
return cond;
EndFunction
Script SayPriorLine ()
if (isInTextEditor()) then
PriorLine();
announceTabs();
sayLine();
else
performScript sayPriorLine();
EndIf
EndScript
Script SayNextLine ()
if (isInTextEditor()) then
NextLine();
announceTabs();
sayLine();
else
PerformScript SayNextLine();
EndIf
EndScript