-
Notifications
You must be signed in to change notification settings - Fork 0
/
SuperSimpleTimeline.sc
1151 lines (990 loc) · 35.4 KB
/
SuperSimpleTimeline.sc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// do we want/need names?
// should this auto number/name within a section?
// yes
// items should be able to be members of multiple groups?
// For now no, just show alignment
// use a priorityQueue to store, but sched on the SST's clock. Since we only ever sched the next event, it's no problem. One issue is clearing the clock's queue, as that may clear other scheduled items. So instead we check if the queue is the same object, and ignore otherwise
// might be simpler to just make it uneditable while playing
SST {
var <>clock, <items, queue, clockStart, nextTime, playOffset;
var <groups, <groupOrder;
var <timeUpdate = 0.04;
var <playing = false;
var <pauseTime = 0;
var <sections;
*new {|clock| ^super.new.init(clock); }
init {|argclock|
clock = argclock ? TempoClock.default;
items = SortedList(128, {|a, b|
a.time < b.time || (a.time == b.time && { a.group.order < b.group.order })
});
groupOrder = List.new;
groups = IdentityDictionary.new;
this.createGroup('Ungrouped', []);
sections = SortedList(8, {|a, b| a.time < b.time });
}
addItem {|item|
groups['Ungrouped'].addItem(item);
items.add(item);
item.sst = this;
this.changed(\items);
}
// we schedule one event at a time, that way we can ignore a scheduled event if its time has changed
// calling this while already playing will rebuild the queue and jump to the new time
play {|startTime = 0| // startTime is relative to the event list
var i = items.lastIndex, item, time, thisQueue;
if(items.size > 0, {
playOffset = startTime;
queue = PriorityQueue.new;
while({(item = items[i]).notNil and: {(time = item.time) >= startTime}}, {
queue.put(time, item);
i = i - 1;
});
// need to deal with beats and quant here...
clockStart = clock.beats;
thisQueue = queue;
clock.sched((nextTime = queue.topPriority) - playOffset, {this.nextEvent(thisQueue)});
if(playing.not, {this.startTimeUpdate });
playing = true;
});
}
pause { pauseTime = this.currentTime; playing = false; queue = nil; }
togglePlay { if(playing, { this.pause }, { this.play(pauseTime) }); }
stop { playing = false; queue = nil; pauseTime = 0; this.changed(\time, 0) }
startTimeUpdate {
clock.sched(0, {
this.changed(\time, this.currentTime);
if(playing, timeUpdate, nil);
})
}
nextEvent {|eventsQueue|
var lastTime, thisQueue = queue, thisItem;
// test that the queue hasn't been edited
// unfortunately, there's no way to remove a single scheduled event from a clock
if(eventsQueue === queue, {
thisItem = queue.pop;
thisItem.value;
this.changed(\itemFired, thisItem);
lastTime = nextTime;
if(queue.notEmpty, {
clock.sched((nextTime = queue.topPriority) - lastTime,
{this.nextEvent(thisQueue)});
}, {playing = false});
});
}
itemAtTime {|time|
^items.detect({|item| item.time == time});
}
removeItem {|item|
items.remove(item);
item.group.removeItem(item);
if(playing, {this.play(clock.beats - clockStart)}); // this will rebuild the queue
this.changed(\items);
}
moveItem {|time, item|
item.time = time;
items.sort;
if(playing, {this.play(clock.beats - clockStart)}); // this will rebuild the queue
this.changed(\itemTimes);
}
shiftItemsLater {|time, firstItem|
var shiftAmount, ind, item;
time = max(time, 0);
shiftAmount = time - firstItem.time;
ind = items.indexOf(firstItem);
for(ind, items.size-1, {|i| item = items[i]; item.time = item.time + shiftAmount });
items.sort;
if(playing, {this.play(clock.beats - clockStart)}); // this will rebuild the queue
this.changed(\itemTimes);
}
//shiftItemsBefore {|lastItem, time| } // don't think we need this
clear {}
createGroup {|groupName, groupItems| // Symbol, Array;
var exists;
exists = groups[groupName];
if(exists.notNil, {
exists.items.do({|item| groups['Ungrouped'].addItem(item) });
exists.items = groupItems;
}, {
groupOrder.add(groupName); // if new add last
groups[groupName] = SSTGroup(groupName, groupItems, groupOrder.indexOf(groupName));
});
this.changed(\groupAdded, groupName);
} // very simple for now
orderGroup {|groupName, index|
groupOrder.remove(groupName);
groupOrder.insert(index, groupName);
this.resetGroupOrders;
}
renameGroup {|oldName, newName|
var group;
group = groups[oldName];
groups[newName] = group.name_(newName);
groups[oldName] = nil;
groupOrder[group.order] = newName;
this.changed(\groupRenamed, oldName, newName);
}
resetGroupOrders {
groupOrder.do({|key, i| groups[key].order = i; });
}
removeGroup {|groupName|
groups[groupName].items.do({|item| groups['Ungrouped'].addItem(item) });
groups[groupName] = nil;
groupOrder.remove(groupName);
this.resetGroupOrders;
this.changed(\groupRemoved, groupName);
}
addSection {|time, name| sections.add((time: time, name: name)); this.changed(\sectionAdded); }
lastEventTime { ^if(items.size > 0, {items.last.time}, {0}); } // more meaningful than duration
currentTime { ^if(playing, {clock.beats - clockStart + playOffset}, { pauseTime }) }
currentTime_ {|time| if(playing, {this.play(time)}, { pauseTime = time }); this.changed(\time, time) }
asRoutineCode {
var resultString, lastEventTime = 0;
var sectionsList, resources = false;
SSTItemWrapper.startResourceCollect;
items.do({|wrapper|
var resourceString;
resourceString = wrapper.resourceCode;
resourceString.notNil.if({
resources = true;
resultString = resultString ++ resourceString;
});
});
SSTItemWrapper.cleanUpResourceCollect;
if(resources, {
resultString = "/////// Routine Generated from SuperSimpleTimeline\n\n// Resource code\n\n(\n" ++ resultString ++ ")\n\n";
});
// now events
resultString = resultString ++ "// Event Code \n\n(\nRoutine({\n\n";
sectionsList = sections.as(Array).reverse;
items.do({|wrapper|
var wait, thisEventCode;
wait = wrapper.time - lastEventTime;
if(wait > 0, {
resultString = resultString ++ "\n\t" ++ wait ++ ".wait;\n\n";
});
while({sectionsList.size > 0 && {wrapper.time >= sectionsList.last.time}}, {
resultString = resultString ++ "/////// Section " ++ sectionsList.pop.name ++ " ///////\n\n";
});
thisEventCode = wrapper.eventCode;
if(thisEventCode.last != $;, {thisEventCode = thisEventCode ++ $;});
resultString = resultString ++ "\t" ++ thisEventCode ++ "\n";
lastEventTime = wrapper.time;
});
resultString = resultString ++ "\n}).play;\n)"
^resultString;
}
asDocument {
Document.new("SST -> Routine", this.asRoutineCode);
}
}
SSTGroup {
var <>name, <items, <>order, <>color;
*new {|name, items, order|
items = SortedList(items.size, {|a, b| a.time <= b.time}).addAll(items);
^super.newCopyArgs(name, items, order).init;
}
init { items.do(_.group = this) }
items_ {|newItems|
items = SortedList(newItems.size, {|a, b| a.time <= b.time}).addAll(newItems);
this.init
}
addItem {|newItem| newItem.group = this; items.add(newItem) }
removeItem {|itemToRemove| items.remove(itemToRemove) }
sort { items.sort }
}
// could contain text, a soundfile, whatever
SSTItemWrapper {
var <time;
var <>wrapped; // the thing that's executed
var <group;
var <>sst;
classvar <resources; // a collection of buffers, etc.
*new {|time, wrapped| ^super.newCopyArgs(max(time, 0), wrapped); }
*cleanUpResourceCollect { resources = nil }
*startResourceCollect { resources = IdentityDictionary.new }
time_ {|newTime| time = max(newTime, 0); group.sort;}
group_ {|newGroup| group !? {|oldGroup| oldGroup.removeItem(this)}; group = newGroup }
gui {|parent, origin, name| ^SSTItemWrapperGUI(this, parent, origin, name) }
// initialisation code for things like buffers and defs
resourceCode { ^nil }
// the code which causes the actual event
eventCode { ^(wrapped.asCompileString ++ ".value;") }
//execute the event
value { wrapped.value }
initFromArchive { }
}
// text to be evaluated
SSTTextWrapper : SSTItemWrapper {
var <text;
// text must be properly escaped if you supply a String literal
*new {|time, text| ^super.new(time, nil).text_(text) }
compileText { wrapped = text.compile }
text_ {|newText| text = newText; this.compileText; }
gui {|parent, origin, name| ^SSTTextWrapperGUI(this, parent, origin, name) }
// the code which causes the actual event
eventCode { ^text }
//execute the event
value { wrapped.value }
}
// play a soundfile from a Buffer
SSTEnvelopedBufferWrapper : SSTItemWrapper {
var <>eventCode, <env, defName, <id;
*new {|time, buffer| ^super.new(time, buffer).init }
init {
env = Env([1, 1], [wrapped.duration]);
id = (this.identityHash%(2.pow(16))).asInteger;
defName = "SST-" ++ id;
this.addDef;
eventCode = "Synth(" ++ defName.asCompileString ++ ", [out: 0, rate: 1, mul: 1], target: " ++ wrapped.server.asCompileString ++ ");";
}
initFromArchive { wrapped = Buffer.read(wrapped.server, wrapped.path, action: { this.addDef}); }
addDef {
SynthDef(defName, {|out, rate, mul|
var output;
output = PlayBufSendIndex.ar(wrapped.numChannels, wrapped, rate, indFreq: 30, id: id);
output = output * EnvGen.ar(env, timeScale: rate.reciprocal, levelScale: mul, doneAction: 2);
Out.ar(out, output);
}).add;
}
env_{|newEnv| env = newEnv; this.addDef }
gui {|parent, origin, name| ^SSTEnvelopedBufferWrapperGUI(this, parent, origin, name) }
// initialisation code for things like buffers and defs
resourceCode {
var bufKey, resourceString = "";
// problem if multiple files with the same name
bufKey = ("sst_buf_" ++ wrapped.path.basename.splitext[0]).asSymbol;
// only add buffers once
if(resources[bufKey].isNil, {
resources[bufKey] = wrapped;
resourceString = resourceString
++ $~
++ bufKey
++ " = Buffer.read("
++ wrapped.server.asCompileString
++ ", "
++ wrapped.path.asCompileString
++ ");\n\n";
});
// use PlayBuf here instead of PlayBufSendIndex
resourceString = resourceString ++
"SynthDef(%, {|out, rate, mul|
var output;
output = PlayBuf.ar(%, ~%, rate);
output = output * EnvGen.ar(%, timeScale: rate.reciprocal, levelScale: mul, doneAction: 2);
Out.ar(out, output);
}).add;\n\n".format(defName.asCompileString, wrapped.numChannels, bufKey, env.asCompileString);
^resourceString
}
//execute the event
value { eventCode.interpret }
}
SSTGUI {
var <sst, eventsView, cursorView, window, name, onClose;
var path, sf, durInv, sfView, scrollView, selectView, backView, timesView;
var selectedItem, selectedStartX, selectXOffset, timePerPixel, itemRects, visOriginOnSelected, selectedRect;
var dependees;
var time, curSSTime, refTime, cursorLoc;
var zoomSlider, labelFont, labelBounds, sectionLabelBounds, brakFont;
var inMove = false, groupDragItem, groupDragRect, groupDraggedTo, groupDragStartX, groupDragStartY;
var selectedLabel, selectedLabelRect;
var groupLabelDragRect, groupLabelDragName, groupLabelDragStartY;
var selectedSectionLabel, selectedSectionLabelRect;
var firedItems, firedEnv, fadeDur = 0.3;
var colorStream;
var <eventGUIs;
var groups;
var width = 1008;
*new {|sst, name, origin|
^super.new.init(sst, name ? "SuperSimpleTimeline").makeWindow(origin ? (200@200));
}
*readSST {|path, origin|
var new;
new = super.new.init(SST.new, name ? "SuperSimpleTimeline").makeWindow(origin ? (200@200)); // a bit ugly
{new.readSST(path)}.defer(0.1);
^new;
}
init {|argSST, argName|
var hexColours;
sst = argSST;
name = argName;
dependees = [sst.addDependant(this)]; // sst is the time ref
groups = sst.groups; // hold a reference to the sst's group dict
firedItems = IdentityDictionary.new;
firedEnv = Env([1, 0], [fadeDur], \sine);
labelFont = Font( Font.defaultSansFace, 10 ).boldVariant;
brakFont = Font( Font.defaultSansFace, 24 ).boldVariant;
labelBounds = IdentityDictionary.new;
sectionLabelBounds = IdentityDictionary.new;
itemRects = IdentityDictionary.new;
/*
http://www.colourlovers.com/palette/2066112/purplexed#
Author: Artsplay http://www.colourlovers.com/lover/artsplay/loveNote
*/
//hexColours = ["#DD9D25", "#C9C748", "#8B1A92", "#DDB137", "#D8D649"];
/*
http://www.colourlovers.com/palette/2066046/MH_Palette
Author: SpotlightNC http://www.colourlovers.com/lover/SpotlightNC/loveNote
*/
hexColours = ["#FF7A17", "#FF1C59", "#FFC424", "#A132CF", "#13945F"];
colorStream = Pseq(hexColours.collect({|hex|
Color.fromHexString(hex);
}), inf).asStream;
sst.groupOrder.do({|grpname|
groups[grpname].color = colorStream.next;
});
eventGUIs = IdentityDictionary.new;
}
groupColours_ { |coloursArray|
colorStream = Pseq(coloursArray, inf).asStream;
sst.groupOrder.do({|grpname|
groups[grpname].color = colorStream.next;
});
eventsView.refresh;
}
groupColoursFromHex_ {|hexArray|
colorStream = Pseq(hexArray.collect({|hex| Color.fromHexString(hex);}), inf).asStream;
sst.groupOrder.do({|grpname|
groups[grpname].color = colorStream.next;
});
eventsView.refresh;
}
makeWindow { |origin|
durInv = max(sst.lastEventTime, 1).reciprocal;
window = Window.new(name, Rect(origin.x, origin.y, width, 400), false);
window.view.decorator = FlowLayout(window.view.bounds);
window.view.keyDownAction = { arg view,char,modifiers,unicode,keycode;
if(unicode == 32, {sst.togglePlay});
if(unicode == 13, {sst.stop});
};
scrollView = ScrollView(window, Rect(0, 0, width - 8, 334));
scrollView.hasBorder = true;
scrollView.resize = 2;
scrollView.hasVerticalScroller = false;
scrollView.canFocus_(false);
backView = CompositeView(scrollView, Rect(0, 20, width - 10, 294)).background_(Color.clear);
this.makeTimesView;
window.onClose = {
dependees.do({|dee| dee.removeDependant(this)});
onClose.value(this);
};
window.view.decorator.shift(0, 5);
StaticText(window, Rect(0, 0, 5, 10)).string_("-").font_(Font("Helvetica-Bold", 12));
zoomSlider = Slider(window, Rect(0, 5, 100, 10)).action_({|view|
var pixelsPerSecond, newWidth;
// pixels per second from whole sequence to 1 second
pixelsPerSecond = [(scrollView.bounds.width - 4) * durInv, (scrollView.bounds.width - 4), \cos].asSpec.map(view.value);
newWidth = (max(sst.lastEventTime, 1) * pixelsPerSecond).round;
backView.bounds = backView.bounds.width_(newWidth);
eventsView.bounds = eventsView.bounds.width_(newWidth);
cursorView.bounds = cursorView.bounds.width_(newWidth);
timesView.bounds = timesView.bounds.width_(newWidth);
timePerPixel = max(sst.lastEventTime, 1) / newWidth;
}).canFocus_(false).enabled_(true);
StaticText(window, Rect(0, 0, 10, 10)).string_("+").font_(Font("Helvetica-Bold", 10));
Button(window, Rect(0, 0, 40, 15))
.states_([["+ group"]])
.font_(Font("Helvetica-Bold", 10))
.canFocus_(false)
.action_({
var groupNameEditor, thisLabel, thisLabelRect;
sst.createGroup('New Group', []);
eventsView.refresh;
{
thisLabelRect = labelBounds['New Group'];
thisLabel = 'New Group';
groupNameEditor = TextField(backView, thisLabelRect.insetBy(-3));
groupNameEditor.background = Color.grey(0.9);
groupNameEditor.font = labelFont;
groupNameEditor.focus(true);
groupNameEditor.keyDownAction = {|view, char, modifiers, unicode, keycode|
if(unicode == 13, {
var newName, index, oldGroup;
newName = view.string.asSymbol;
if(view.string.size > 0 && { sst.groups.keys.includes(newName).not }, {
sst.renameGroup(thisLabel, newName);
});
eventsView.focus(true);
groupNameEditor.remove;
true
}, { nil });
};
}.defer(0.1);
});
window.view.decorator.shift(0, -5);
window.front;
this.makeEventsView;
timePerPixel = max(sst.lastEventTime, 1) / eventsView.bounds.width;
window.view.decorator.nextLine.nextLine;
window.view.decorator.shift(10, 0);
refTime = StaticText(window, Rect(0, 0, 320, 25))
.string_("Time:") // initialise
.font_(Font("Helvetica-Bold", 16));
//time = BMTimeReferences.currentTime(ca.timeReference);
time = sst.currentTime;
cursorLoc = time * durInv * cursorView.bounds.width;
refTime.string_("Time:" + time.asTimeString);
window.view.decorator.shift(0, 4);
// curSSTime = SCStaticText(window, Rect(0, 0, 300, 20))
// .string_("Selected Snapshot Time:") // initialise
// .font_(Font("Helvetica-Bold", 12));
//
// if(activeSnapshot.notNil, {
// curSSTime.string_("Selected Snapshot Time:" + activeSnapshot.time.asTimeString);
// });
//zoomSlider.doAction; // hack to make eventsView take mouseDown initially
}
makeTimesView {
timesView.notNil.if({timesView.remove});
timesView = UserView(scrollView, Rect(0, 0, backView.bounds.width, 20));
timesView.background = Color.clear;
timesView.canFocus_(false);
timesView.drawFunc = {
var oneSec, tenSecs, thirtySecs, bounds, halfHeight;
bounds = timesView.bounds;
// background
Pen.addRect(Rect(0, 0, bounds.width, 20));
Pen.fillColor = Color.black.alpha_(0.6);
Pen.fill;
// ticks
halfHeight = bounds.height * 0.5;
DrawGrid(bounds.copy.height_(halfHeight).top_(halfHeight), [0, max(sst.lastEventTime, 1), 'lin', 1.0].asSpec.grid, BlankGridLines()).fontColor_(Color.clear).gridColors_(Color.grey(0.7) ! 2).draw;
tenSecs = timesView.bounds.width * durInv * 10;
Pen.beginPath;
// Pen.strokeColor = Color.grey(0.8);
// (sst.lastEventTime / 10).floor.do({|i|
// var x;
// if((i + 1)%3 == 0, {
// Pen.width = 2;
// Pen.lineDash_(FloatArray[1.0, 0]);
// }, {
// Pen.width = 1;
// Pen.lineDash_(FloatArray[3,3]);
// });
// x = (i + 1) * tenSecs;
// Pen.line(x@20, x@0);
// Pen.stroke;
// });
// Pen.width = 1;
// Pen.lineDash_(FloatArray[]);
thirtySecs = bounds.width * durInv * 30;
(sst.lastEventTime / 10).floor.do({|i|
((i + 1) * 10).asTimeString(1).drawLeftJustIn(
Rect((i+1) * tenSecs + 2, 0, 70, 20),
Font("Helvetica-Bold", 11),
Color.grey(0.8)
);
});
// if(thirtySecs >= scrollView.bounds.width, {
// oneSec = timesView.bounds.width * durInv;
// Pen.strokeColor = Color.grey(0.8);
// sst.lastEventTime.floor.do({|i|
// var x;
// if(i%10 != 0, {
// Pen.lineDash_(FloatArray[1.0, 0.0]);
// x = i * oneSec;
// Pen.line(x@20, x@10);
// Pen.stroke;
// });
// });
// });
Pen.strokeColor = Color.black;
Pen.lineDash_(FloatArray[3,3]);
Pen.line(0@20, bounds.width@20);
Pen.stroke;
Pen.lineDash_(FloatArray[1.0, 0.0]);
// draw section labels
Pen.strokeColor = Color.grey;
Pen.width = 1;
Pen.fillColor = Color.grey(0.75);
sst.sections.do({|section|
var x, sectName, thisSectionLabelBounds;
x = durInv * section.time * eventsView.bounds.width;
sectName = section.name;
sectName.isNil.if({ sectName = " " }); // selection space for unnamed
thisSectionLabelBounds = GUI.current.stringBounds(sectName, labelFont);
thisSectionLabelBounds = thisSectionLabelBounds.moveToPoint(Point(x, 5));
sectionLabelBounds[section] = thisSectionLabelBounds;
Pen.fillRect(thisSectionLabelBounds.insetBy(-1.5));
Pen.stringInRect(sectName, thisSectionLabelBounds, labelFont, Color.grey(0.3));
});
};
timesView.mouseUpAction = {
selectedSectionLabelRect = nil;
selectedSectionLabel = nil;
refTime.string_("Time:" + sst.currentTime.asTimeString);
};
timesView.mouseDownAction = {|view, x, y, modifiers, buttonNumber, clickCount|
// if that fails try for a label
sectionLabelBounds.keysValuesDo({|section, rect|
if(rect.contains((x@y)), {
selectedSectionLabelRect = rect; selectedSectionLabel = section;
})
});
// single (maybe drag) or double (open event gui) click
if(clickCount < 2, {
selectedSectionLabelRect.notNil.if({
visOriginOnSelected = scrollView.visibleOrigin;
selectXOffset = x - visOriginOnSelected.x;
selectedStartX = durInv * selectedSectionLabel.time * eventsView.bounds.width;
refTime.string_("Selected Time:" + selectedSectionLabel.time.asTimeString);
}, {sst.currentTime = x * timePerPixel;});
}, {
selectedSectionLabel.notNil.if({
// we've double clicked on a label
var sectionNameEditor, sectionNameEditorBounds, thisLabel;
thisLabel = selectedSectionLabel;
sectionNameEditorBounds = selectedSectionLabelRect.insetBy(-3);
sectionNameEditorBounds.width = max(sectionNameEditorBounds.width, 60);
sectionNameEditor = TextField(timesView, sectionNameEditorBounds);
sectionNameEditor.background = Color.grey(0.9);
sectionNameEditor.string = selectedSectionLabel.name;
sectionNameEditor.font = labelFont;
sectionNameEditor.focus(true);
sectionNameEditor.keyDownAction = {|view, char, modifiers, unicode, keycode|
if(unicode == 13, {
var newName, index, oldGroup;
newName = view.string;
if(view.string.size > 0
&& { sst.sections.detect({|item| item.name == newName}).isNil }, {
thisLabel.name = newName;
timesView.refresh;
});
eventsView.focus(true);
sectionNameEditor.remove;
true
}, { nil });
};
});
});
};
timesView.mouseMoveAction = {|view, x, y|
var time;
var visRange, newX, lastX, maxX;
selectedSectionLabelRect.notNil.if({
inMove = true;
// get some info
// moving can cause scrolling, so calc distance of x from vis origin
lastX = sst.lastEventTime * durInv * eventsView.bounds.width;
visRange = Range(scrollView.visibleOrigin.x, scrollView.bounds.width);
newX = (x - visRange.start - selectXOffset) + selectedStartX; // could be more than lastX
time = newX * timePerPixel;
selectedSectionLabel.time = min(time, sst.lastEventTime);
refTime.string_("Selected Time:" + selectedSectionLabel.time.asTimeString);
// now check if we can see newX and scroll if needed
if(visRange.start > newX, {
scrollView.visibleOrigin = newX@scrollView.visibleOrigin.y;
});
if(visRange.end < newX, {
scrollView.visibleOrigin = (newX - scrollView.bounds.width + 25)@scrollView.visibleOrigin.y;
});
timesView.refresh;
cursorView.refresh;
}, {
// drag the time cursor
sst.currentTime = min(x * timePerPixel, sst.lastEventTime);
});
};
}
makeEventsView {
cursorView.notNil.if({cursorView.remove});
eventsView.notNil.if({eventsView.remove});
scrollView.action = { eventsView.refresh }; // for now. Could but labels in a separate lower view
cursorView = UserView(backView, Rect(0, 0, backView.bounds.width, backView.bounds.height))
.canFocus_(false)
.background_(Color.clear);
eventsView = UserView(backView, Rect(0, 0, backView.bounds.width, backView.bounds.height))
.canFocus_(false)
.background_(Color.clear);
cursorView.drawFunc = {
// draw grid
DrawGrid(eventsView.bounds, [0, max(sst.lastEventTime, 1), 'lin', 1.0].asSpec.grid, BlankGridLines()).draw;
// draw section markers
Pen.strokeColor = Color.grey;
Pen.width = 1;
sst.sections.do({|section|
var x;
x = durInv * section.time * eventsView.bounds.width - 2.5;
Pen.line(x@0, x@(eventsView.bounds.height - 15));
x = x+5;
Pen.line(x@0, x@(eventsView.bounds.height - 15));
Pen.stroke;
});
// draw time cursor
Pen.strokeColor = Color.grey;
Pen.width = 2;
Pen.line(cursorLoc@0, cursorLoc@eventsView.bounds.height);
Pen.stroke;
// draw fired rings
firedItems.copy.keysValuesDo({|firedItem, itemSpecs|
var x, rect, alpha;
x = durInv * firedItem.time * eventsView.bounds.width;
rect = Rect.aboutPoint(x@itemSpecs.groupY, 14, 14);
alpha = itemSpecs.alpha;
if(alpha == 0, { firedItems[firedItem] = nil; }); // remove if done
Pen.fillColor = Color.white.alpha_(alpha);
//Pen.width = 3;
Pen.fillOval(rect);
//Pen.strokeOval(rect);
});
};
eventsView.drawFunc = {
var stringX = scrollView.visibleOrigin.x + 4;
groupDraggedTo = nil;
Pen.strokeColor = Color.black;
//Pen.fillColor = Color.grey;
sst.groupOrder.do({|name, i|
var groupY, labelPoint, label, thisLabelBounds;
// draw labels
if(groupLabelDragName == name, {
label = (i + 1).asString ++ ". " ++ name.asString;
labelPoint = stringX@groupLabelDragRect.top;
labelBounds[name] = thisLabelBounds = GUI.current.stringBounds(label, labelFont).moveToPoint(labelPoint);
},{
label = (i + 1).asString ++ ". " ++ name.asString;
labelPoint = stringX@(i * 40 + 5);
labelBounds[name] = thisLabelBounds = GUI.current.stringBounds(label, labelFont).moveToPoint(labelPoint);
});
if(groupDragItem.notNil && { thisLabelBounds.intersects(groupDragRect) }, {
Pen.fillColor = Color.white.alpha_(0.6);
Pen.fillRect(thisLabelBounds.resizeBy(4, 4).moveBy(-2, -2));
groupDraggedTo = name;
});
Pen.stringAtPoint(label, labelPoint, labelFont, Color.grey(0.3));
groupY = thisLabelBounds.top + 25; // y for the events, not the labels
// draw brackets
if(name != 'Ungrouped' && (sst.groups[name].items.size.postln > 0), {
var openX, closeX, brakSize;
brakSize = GUI.current.stringBounds("[", brakFont);
openX = sst.groups[name].items.first.time * durInv * eventsView.bounds.width - (brakSize.width * 2.5);
closeX = sst.groups[name].items.last.time * durInv * eventsView.bounds.width + (brakSize.width * 1.5);
Pen.stringAtPoint("[", openX@(groupY - (brakSize.height * 0.5)), brakFont, Color.grey(0.6));
Pen.stringAtPoint("]", closeX@(groupY - (brakSize.height * 0.5)), brakFont, Color.grey(0.6));
});
// draw events
Pen.fillColor = groups[name].color;
sst.groups[name].items.reverseDo({|item| // draw earlier items on top
var x, rect;
x = durInv * item.time * eventsView.bounds.width;
rect = Rect.aboutPoint(x@groupY, 10, 10);
Pen.width = 1;
Pen.fillOval(rect);
Pen.strokeOval(rect);
itemRects[item] = rect;
});
});
// draw group drag if needed
if(groupDragItem.notNil, {
Pen.width = 1;
Pen.strokeColor = Color.grey;
Pen.lineDash = FloatArray[3.0, 1.0];
Pen.strokeOval(groupDragRect);
Pen.lineDash = FloatArray[1.0, 0.0];
});
};
eventsView.mouseMoveAction = {|view, x, y, modifiers|
var time;
var visRange, newX, lastX, maxX;
if(selectedItem.notNil, {
// doing something with an event
if(groupDragItem.notNil, { // drag item to a group
groupDragRect = selectedRect.moveBy(x - groupDragStartX, y - groupDragStartY);
eventsView.refresh;
}, { // vanilla move or shift
inMove = true;
// get some info
// moving can cause scrolling, so calc distance of x from vis origin
lastX = sst.lastEventTime * durInv * eventsView.bounds.width;
visRange = Range(scrollView.visibleOrigin.x, scrollView.bounds.width);
newX = (x - visRange.start - selectXOffset) + selectedStartX; // could be more than lastX
time = newX * timePerPixel;
// move or shift
if(modifiers.isShift, {
sst.shiftItemsLater(time, selectedItem);
}, {
sst.moveItem(time, selectedItem);
});
refTime.string_("Selected Time:" + time.asTimeString);
// now check if we can see newX and scroll if needed
if(visRange.start > newX, {
scrollView.visibleOrigin = newX@scrollView.visibleOrigin.y;
});
if(visRange.end < newX, {
scrollView.visibleOrigin = (newX - scrollView.bounds.width + 25)@scrollView.visibleOrigin.y;
});
if(modifiers.isShift, { timesView.refresh; cursorView.refresh; });
});
}, {
if(groupLabelDragName.notNil, {
// dragging a group label
groupLabelDragRect = selectedLabelRect.moveBy(0, y - groupLabelDragStartY);
eventsView.refresh;
});
});
};
eventsView.mouseUpAction = {|view|
inMove = false;
if(groupDragItem.notNil, {
if(groupDraggedTo.notNil, { sst.groups[groupDraggedTo].addItem(groupDragItem); });
groupDragItem = nil;
groupDragRect = nil;
eventsView.refresh;
}, {
if(groupLabelDragName.notNil, {
var newInd;
newInd = this.indexOfDraggedLabelBounds(groupLabelDragRect);
sst.orderGroup(groupLabelDragName, newInd);
groupLabelDragName = nil;
groupLabelDragStartY = nil;
groupLabelDragRect = nil;
eventsView.refresh;
});
});
refTime.string_("Time:" + time.asTimeString);
};
eventsView.mouseDownAction = {|view, x, y, modifiers, buttonNumber, clickCount|
selectedLabel = nil;
selectedLabelRect = nil;
// find selected event
selectedRect = nil;
selectedItem = nil;
itemRects.keysValuesDo({|item, rect|
if(rect.contains((x@y)), {selectedRect = rect; selectedItem = item;})
});
// if that fails try for a label
if(selectedRect.isNil, {
labelBounds.keysValuesDo({|name, rect|
if(rect.contains((x@y)), {
selectedLabelRect = rect; selectedLabel = name;
})
});
});
if(clickCount < 2, {
// singleClick, could be item-toGroup or label drag
selectedRect.notNil.if({
// we're dragging an event
refTime.string_("Selected Time:" + selectedItem.time.asTimeString);
visOriginOnSelected = scrollView.visibleOrigin;
selectXOffset = x - visOriginOnSelected.x;
selectedStartX = durInv * selectedItem.time * eventsView.bounds.width;
if(modifiers.isCtrl, {
// we're dragging an event to a group
groupDragStartX = x;
groupDragStartY = y;
groupDragItem = selectedItem;
groupDragRect = selectedRect;
});
}, {
if(selectedLabelRect.notNil && modifiers.isCtrl, {
// we're dragging a group label
groupLabelDragStartY = y;
groupLabelDragRect = selectedLabelRect;
groupLabelDragName = selectedLabel;
});
});
}, {
// doubleClick
selectedItem.notNil.if({
// pop open item editor
var thisGUI, thisItem;
thisGUI = eventGUIs[selectedItem];
if(thisGUI.notNil, { thisGUI.front }, {
thisItem = selectedItem;
eventGUIs[thisItem] = thisGUI = thisItem.gui;
thisGUI.notNil.if({
sst.addDependant(thisGUI);
thisGUI.onClose = {
eventGUIs[thisItem] = nil;
sst.removeDependant(thisGUI);
};
});
});
}, {
(selectedLabel.notNil && (selectedLabel != 'Ungrouped')).if({
// edit group label
var groupNameEditor, thisLabel;
thisLabel = selectedLabel;
groupNameEditor = TextField(backView, selectedLabelRect.insetBy(-3));
groupNameEditor.background = Color.grey(0.9);
groupNameEditor.string = selectedLabel.asString;
groupNameEditor.font = labelFont;
groupNameEditor.focus(true);
groupNameEditor.keyDownAction = {|view, char, modifiers, unicode, keycode|
if(unicode == 13, {
var newName, index, oldGroup;
newName = view.string.asSymbol;
if(view.string.size > 0 && { sst.groups.keys.includes(newName).not }, {
sst.renameGroup(thisLabel, newName);
});
eventsView.focus(true);
groupNameEditor.remove;
true
}, { nil });
};
}, {
// make a new event
var newEventTime, newEvent, thisLabelDist;
var closestLabelDist = inf, newEventLabel;
newEventTime = x * timePerPixel;
sst.addItem(newEvent = SSTTextWrapper(newEventTime, ""));
labelBounds.keysValuesDo({|name, bounds|
thisLabelDist = abs(bounds.bottom - y);
if(thisLabelDist <= closestLabelDist, {
closestLabelDist = thisLabelDist;
newEventLabel = name;
});
});
sst.groups[newEventLabel].addItem(newEvent);
{ newEvent.gui }.defer(0.1);
});
});
});
};
}
// this finds the new index for a dragged group label
indexOfDraggedLabelBounds {|draggedBounds|
^labelBounds.values.asArray.sort({|a, b| a.top < b.top }).indexOfEqual(draggedBounds);
}
recalcZoom {
// don't fire action, just get it in the right place
zoomSlider.value = [(scrollView.bounds.width - 4) * durInv, (scrollView.bounds.width - 4), \cos]
.asSpec
.unmap(timePerPixel.reciprocal);
}
resizeInternalViewsIfNeeded {