-
Notifications
You must be signed in to change notification settings - Fork 0
/
railbuilder.nut
1748 lines (1643 loc) · 74.3 KB
/
railbuilder.nut
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/**
* This file is part of WormAI: An OpenTTD AI.
*
* @file railbuilder.nut Containing the Rail Builder and related classes for WormAI.
* Based on code from SimpleAI.
*
* License: GNU GPL - version 2 (see license.txt)
* Author: Wormnest (Jacob Boerema)
* Copyright: Jacob Boerema, 2016.
*
*/
const DIR_NE = 2;
const DIR_NW = 0;
const DIR_SE = 1;
const DIR_SW = 3;
/**
* Define WormStation class containing station building info.
*/
class WormStation
{
statile = null; ///< The tile of the station
deptile = null; ///< The tile of the depot
stafront = null; ///< The tile in front of the station
depfront = null; ///< The tile in front of the depot
statop = null; ///< The top tile of the station
stabottom = null; ///< The bottom tile of the station
frontfront = null; ///< ...
stationdir = null; ///< The direction of the station
optimaldir = null; ///< The optimal direction from one station to the other
stasrc = null; ///< Station ID of source station
stadst = null; ///< Station ID of destination station
homedepot = null; ///< The depot at the source station
// Below only used only for "double" station
front1 = null;
front2 = null;
lane2 = null;
morefront = null;
constructor() {}
}
class WormRailPathFinder extends Rail
{
// _cost_level_crossing = null;
}
/**
* Overrides the rail pathfinder's _Cost function to add a penalty for level crossings.
* DISABLED. Now part of our pathfinder code.
*
function WormRailPathFinder::_Cost(path, new_tile, new_direction, self)
{
local cost = ::Rail._Cost(path, new_tile, new_direction, self);
if (AITile.HasTransportType(new_tile, AITile.TRANSPORT_ROAD)) cost += self._cost_level_crossing;
return cost;
} */
/**
* Define the WormRailBuilder class which handles trains.
*/
class WormRailBuilder
{
/**
* Get a TileList around a town.
* @param town_id The TownID of the given town.
* @param width The width of the proposed station.
* @param height The height of the proposed station.
* @return A TileList containing tiles around a town.
*/
function GetTilesAroundTown(town_id, width, height);
/**
* Choose a rail wagon for the given cargo.
* @param cargo The cargo which will be transported by te wagon.
* @return The EngineID of the chosen wagon, null if no suitable wagon was found.
*/
static function ChooseWagon(cargo, blacklist);
/**
* Choose a train locomotive.
* @param cargo The cargo to carry.
* @param distance The distance to be traveled.
* @param wagon The EngineID of the wagons to be pulled.
* @param num_wagons The number of wagons to be pulled.
* @param blacklist A list of engines that cannot be used.
* @return The EngineID of the chosen locomotive, null if no suitable locomotive was found.
*/
static function ChooseTrainEngine(cargo, distance, wagon, num_wagons, blacklist);
/**
* A valuator function for scoring train locomotives.
* @param engine The engine to be scored.
* @param weight The weight to be pulled.
* @param max_speed The maximum speed allowed.
* @param money The amount of money the company has.
* @return The score of the engine.
* @todo the money parameter seems not to be used.
*/
static function TrainEngineValuator(engine, weight, max_speed, money);
/**
* Build a single (one-lane) rail station at a town or an industry.
* Builder class variables used: crg, src, dst, srcplace, dstplace, srcistown, dstistown,
* statile, stafront, depfront, frontfront, statop, stationdir
* Builder class variables set: stasrc, stadst, homedepot
* @param is_source True if we are building the source station.
* @param platform_length The length of the new station's platform.
* @param route_data A WormRoute class object containing info about the route.
* @param station_data A WormStation class object containing info about the station.
* @param rail_manager The WormRailManager class object.
* @return True if the construction succeeded.
*/
function BuildSingleRailStation(is_source, platform_length, route_data, station_data, rail_manager);
/**
* Check whether a single rail station can be built at the given position.
* Builder class variables set: statop, stabotton, statile, stafront, depfront, frontfront
* @param tile The tile to be checked.
* @param direction The direction of the proposed station.
* @param platform_length The length of the proposed station's platform.
* @param station_data WormStation class object where the build info will be store (should be non null when called).
* @return True if a single rail station can be built at the given position.
*/
function CanBuildSingleRailStation(tile, direction, platform_length, station_data);
/**
* Build a rail station at a town or an industry.
* @param is_source True if we are building the source station.
* @param lanes The number of lanes (platforms). Currently only 1 or 2 is supported.
* @param platform_length The length of the proposed station's platform.
* @param route_data A WormRoute class object containing info about the route.
* @param station_data A WormStation class object containing info about the station.
* @param rail_manager The WormRailManager class object.
* @return True if the construction succeeded.
* @pre lanes > 0 and < 3; route_data, station_data and rail_manager should be valid (non null).
* @todo Support more than 2 lanes.
*/
function BuildRailStation(is_source, lanes, platform_length, route_data, station_data, rail_manager);
/**
* Determine whether a rail station can be built at a given place.
* @param tile The tile to be checked.
* @param lanes The number of lanes (platforms). Currently only 1 or 2 is supported.
* @param direction The direction of the proposed station.
* @param platform_length The length of the proposed station's platform.
* @param station_data WormStation class object where the build info will be store (should be non null when called).
* @return True if a double rail station can be built at the given position.
* @todo Support more than 2 lanes.
*/
function CanBuildRailStation(tile, lanes, direction, platform_length, station_data);
/**
* Build a rail line between two given points.
* @param head1 The starting points of the rail line.
* @param head2 The ending points of the rail line.
* @param railbridges The list of railbridges. If we need to build a bridge it will be added to this list.
* @return True if the construction succeeded.
*/
function BuildRail(head1, head2, railbridges);
/**
* Build a rail line between two given points.
* @param head1 The starting points of the rail line.
* @param head2 The ending points of the rail line.
* @param railbridges The list of railbridges. If we need to build a bridge it will be added to this list.
* @param recursiondepth The recursion depth used to catch infinite recursions.
* @return True if the construction succeeded.
*/
function InternalBuildRail(head1, head2, railbridges, recursiondepth);
/**
* Retry building a rail track after it was interrupted. The last three pieces of track
* are removed, and then pathfinding is restarted from the other end.
* @param prevprev The last successfully built piece of track.
* @param pp1 The piece of track before prevprev.
* @param pp2 The piece of track before pp1.
* @param pp3 The piece of track before pp2. It is not removed.
* @param head1 The other end to be connected.
* @param railbridges The list of railbridges. If we need to build a bridge it will be added to this list.
* @param recursiondepth The recursion depth used to catch infinite recursions.
* @return True if the construction succeeded.
*/
function RetryRail(prevprev, pp1, pp2, pp3, head1, railbridges, recursiondepth);
/**
* Build a passing lane section between the current source and destination.
* Builder class variables used: stasrc, stadst
* @param near_source True if we're building the first passing lane section. (the one closer to the source station)
* @param train_length The maximum train length in tiles that should fit (should be at least 3).
* @param station_data A WormStation class object with info about the stations between which rail is being built.
* @param rail_manager The WormRailManager class object.
* @return True if the construction succeeded.
*/
function BuildPassingLaneSection(near_source, train_length, station_data, rail_manager);
/**
* Determine whether a passing lane section can be built at a given position.
* @param centre The centre tile of the proposed passing lane section.
* @param direction The direction of the proposed passing lane section.
* @param reverse True if we are trying to build a flipped passing lane section.
* @param train_length The maximum train length in tiles that should fit (should be at least 3).
* @return True if a passing lane section can be built.
*/
function CanBuildPassingLaneSection(centre, direction, reverse, train_length);
/**
* Build and start trains for the current route.
* @param number The number of trains to be built.
* @param length The number of wagons to be attached to the train.
* @param engine The EngineID of the locomotive.
* @param wagon The EngineID of the wagons.
* @param ordervehicle The vehicle to share orders with. Null, if there is no such vehicle.
* @param group The vehicle group this train should be part of.
* @param cargo The cargo to transport.
* @param station_data A WormStation class object with info about the stations between which rail is being built.
* @param engineblacklist The blacklist of engines to which bad engines will be added.
* @return True if at least one train was built.
*/
function BuildAndStartTrains(number, length, engine, wagon, ordervehicle, group, cargo, station_data, engineblacklist);
/**
* A workaround for refitting the mail wagon separately.
* @param mailwagon The mail wagon to be refitted.
* @param firstwagon The wagon to which the mail wagon is attached.
* @param trainengine The locomotive of the train, used to move the wagons.
* @param crg The cargo which the mail wagon will be refitted to.
*/
function MailWagonWorkaround(mailwagon, firstwagon, trainengine, crg);
/**
* Remove one piece of rail track from tile.
* @param tile The tile that has the rail track that needs to be removed.
*/
function RemoveRailFromTile(tile);
/**
* Remove a continuous segment of rail track starting from a single point. This includes depots
* and stations, in all directions and braches. Basically the function deletes all rail tiles
* which are reachable by a train from the starting point. This function is not static.
* @param start_tile The starting point of the rail.
* @param rail_manager The WormRailManager class object.
*/
function RemoveRailLine(start_tile, rail_manager);
/**
* Determine whether two tiles are connected with rail directly.
* @param tilefrom The first tile to check.
* @param tileto The second tile to check.
* @return True if the two tiles are connected.
*/
function AreRailTilesConnected(tilefrom, tileto);
/**
* Delete a rail station together with the rail line.
* Builder class variables used and set:
* @param sta The StationID of the station to be deleted.
* @param rail_manager The WormRailManager class object.
*/
function DeleteRailStation(sta, rail_manager);
/**
* Upgrade a segment of normal rail to electrified rail from a given starting point.
* Tiles which are reachable by a train from a given starting point are electrified,
* including stations and depots. This function is not static.
* @param start_tile The starting point from which rails are electrified.
* @param rail_manager The WormRailManager class object.
*/
function ElectrifyRail(start_tile, rail_manager);
/**
* Get the platform length of a station.
* @param sta The StationID of the station.
* @return The length of the station's platform in tiles.
*/
function GetRailStationPlatformLength(sta);
/**
* Attach more wagons to a train after it has been sent to the depot.
* @param vehicle The VehicleID of the train.
* @param rail_manager The WormRailManager class object.
*/
function AttachMoreWagons(vehicle, rail_manager);
}
function WormRailBuilder::GetTilesAroundTown(town_id, width, height)
{
local tiles = AITileList();
local townplace = AITown.GetLocation(town_id);
local distedge = AIMap.DistanceFromEdge(townplace);
local offset = null;
local radius = 15;
if (AITown.GetPopulation(town_id) > 5000) radius = 30;
// A bit different is the town is near the edge of the map
if (distedge < radius + 1) {
offset = AIMap.GetTileIndex(distedge - 1, distedge - 1);
} else {
offset = AIMap.GetTileIndex(radius, radius);
}
tiles.AddRectangle(townplace - offset, townplace + offset);
tiles.Valuate(WormRailManager.IsRectangleWithinTownInfluence, town_id, width, height);
tiles.KeepValue(1);
return tiles;
}
function WormRailBuilder::ChooseWagon(cargo, blacklist)
{
local wagonlist = AIEngineList(AIVehicle.VT_RAIL);
wagonlist.Valuate(AIEngine.CanRunOnRail, AIRail.GetCurrentRailType());
wagonlist.KeepValue(1);
wagonlist.Valuate(AIEngine.IsWagon);
wagonlist.KeepValue(1);
wagonlist.Valuate(AIEngine.CanRefitCargo, cargo);
wagonlist.KeepValue(1);
wagonlist.Valuate(AIEngine.IsArticulated);
// Only remove articulated wagons if there are non-articulated ones left
local only_articulated = true;
foreach (wagon, articulated in wagonlist) {
if (articulated == 0) {
only_articulated = false;
break;
}
}
if (!only_articulated) {
wagonlist.KeepValue(0);
}
if (blacklist != null) {
wagonlist.Valuate(WormValuators.ListContainsValuator, blacklist);
wagonlist.KeepValue(0);
}
wagonlist.Valuate(AIEngine.GetCapacity);
if (wagonlist.Count() == 0) return null;
return wagonlist.Begin();
}
function WormRailBuilder::ChooseTrainEngine(cargo, distance, wagon, num_wagons, blacklist)
{
local enginelist = AIEngineList(AIVehicle.VT_RAIL);
enginelist.Valuate(AIEngine.HasPowerOnRail, AIRail.GetCurrentRailType());
enginelist.KeepValue(1);
enginelist.Valuate(AIEngine.IsWagon);
enginelist.KeepValue(0);
enginelist.Valuate(AIEngine.CanPullCargo, cargo);
enginelist.KeepValue(1);
if (blacklist != null) {
enginelist.Valuate(WormValuators.ListContainsValuator, blacklist);
enginelist.KeepValue(0);
}
if (enginelist.IsEmpty()) return null;
// @todo the money parameter seems not to be used.
//local money = Banker.GetMaxBankBalance();
local money = 0;
local cargo_weight_factor = 0.5;
if (AICargo.HasCargoClass(cargo, AICargo.CC_PASSENGERS)) cargo_weight_factor = 0.05;
if (AICargo.HasCargoClass(cargo, AICargo.CC_BULK) || AICargo.HasCargoClass(cargo, AICargo.CC_LIQUID))
cargo_weight_factor = 1;
local weight = num_wagons * (AIEngine.GetWeight(wagon) + AIEngine.GetCapacity(wagon) * cargo_weight_factor);
local max_speed = AIEngine.GetMaxSpeed(wagon);
if (max_speed == 0) max_speed = 500;
//AILog.Info("Weight: " + weight + " Max speed: " + max_speed);
// @todo the money parameter seems not to be used.
enginelist.Valuate(WormRailBuilder.TrainEngineValuator, weight, max_speed, money);
local i = 0;
/*foreach (engine, value in enginelist) {
i++;
AILog.Info(i + ". " + AIEngine.GetName(engine) + " - " + value);
}*/
return enginelist.Begin();
}
function WormRailBuilder::TrainEngineValuator(engine, weight, max_speed, money)
{
local value = 0;
local weight_with_engine = weight + AIEngine.GetWeight(engine);
//local hp_break = weight_with_engine.tofloat() * 3.0;
//local power = AIEngine.GetPower(engine).tofloat();
//value += (power > hp_break) ? (160 + 240 * power / (3 * hp_break)) : (240 * power / hp_break);
local hp_per_tonne = AIEngine.GetPower(engine).tofloat() / weight_with_engine.tofloat();
local power_points = (hp_per_tonne > 4.0) ? ((hp_per_tonne > 16.0) ? (620 + 10 * hp_per_tonne / 4.0) :
(420 + 60 * hp_per_tonne / 4.0)) : (-480 + 960 * hp_per_tonne / 4.0);
value += power_points;
local speed = AIEngine.GetMaxSpeed(engine);
local speed_points = (speed > max_speed) ? (360 * max_speed / 112.0) : (360 * speed / 112.0)
value += speed_points;
local runningcost_limit = (6000 / Money.GetInflationRate()).tointeger();
local runningcost = AIEngine.GetRunningCost(engine).tofloat();
local runningcost_penalty = (runningcost > runningcost_limit) ? ((runningcost > 3 * runningcost_limit) ?
(runningcost / 20.0 - 550.0) : (runningcost / 40.0 - 100.0)) : (runningcost / 120.0)
value -= runningcost_penalty;
/*AILog.Info(AIEngine.GetName(engine) + " : " + value);
AILog.Info(" power points: " + power_points);
AILog.Info(" speed points: " + speed_points);
AILog.Info(" running cost penalty: " + runningcost_penalty);
AILog.Info(" railtype: " + AIEngine.GetRailType(engine))*/
return value.tointeger();
}
function WormRailBuilder::BuildSingleRailStation(is_source, platform_length, route_data, station_data, rail_manager)
{
local dir, tilelist, otherplace, isneartown = null;
local rad = AIStation.GetCoverageRadius(AIStation.STATION_TRAIN);
// Determine the direction of the station, and get tile lists
if (is_source) {
dir = WormTiles.GetDirection(route_data.SourceLocation, route_data.DestLocation);
station_data.optimaldir = dir; // Should only be set for source
if (route_data.SourceIsTown) {
tilelist = WormRailBuilder.GetTilesAroundTown(route_data.SourceID, 1, 1);
isneartown = true;
} else {
tilelist = AITileList_IndustryProducing(route_data.SourceID, rad);
isneartown = false;
}
otherplace = route_data.DestLocation;
} else {
dir = WormTiles.GetDirection(route_data.DestLocation, route_data.SourceLocation);
if (route_data.DestIsTown) {
tilelist = WormRailBuilder.GetTilesAroundTown(route_data.DestID, 1, 1);
isneartown = true;
} else {
tilelist = AITileList_IndustryAccepting(route_data.DestID, rad);
tilelist.Valuate(AITile.GetCargoAcceptance, route_data.Cargo, 1, 1, rad);
tilelist.RemoveBelowValue(8);
isneartown = false;
}
otherplace = route_data.SourceLocation;
}
tilelist.Valuate(AITile.IsBuildable);
tilelist.KeepValue(1);
// Sort the tile list
if (isneartown) {
tilelist.Valuate(AITile.GetCargoAcceptance, route_data.Cargo, 1, 1, rad);
tilelist.KeepAboveValue(10);
} else {
tilelist.Valuate(AIMap.DistanceManhattan, otherplace);
}
tilelist.Sort(AIList.SORT_BY_VALUE, !isneartown);
local success = false;
foreach (tile, dummy in tilelist) {
// Find a place where the station can bee built
if (WormRailBuilder.CanBuildSingleRailStation(tile, dir, platform_length, station_data)) {
success = true;
break;
} else continue;
}
if (!success) return false;
// Build the station itself
// @todo The setting "newgrf_stations" was taken from SimpleAI and is currently not available
// as a setting in our AI so this if will currently always return false.
if (AIController.GetSetting("newgrf_stations") == 1 && !route_data.SourceIsTown && !route_data.DestIsTown) {
// Build a NewGRF rail station
success = success && AIRail.BuildNewGRFRailStation(station_data.statop, station_data.stationdir,
1, platform_length, AIStation.STATION_NEW, route_data.Cargo,
AIIndustry.GetIndustryType(route_data.SourceID), AIIndustry.GetIndustryType(route_data.DestID),
AIMap.DistanceManhattan(route_data.SourceLocation, route_data.DestLocation), is_source);
} else {
// Build a standard railway station
success = success && AIRail.BuildRailStation(station_data.statop, station_data.stationdir, 1,
platform_length, AIStation.STATION_NEW);
}
if (!success) {
AILog.Error("Station could not be built: " + AIError.GetLastErrorString());
return false;
}
// Build the rails and the depot
success = success && AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.stafront);
success = success && AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.deptile);
success = success && AIRail.BuildRail(station_data.deptile, station_data.depfront, station_data.stafront);
success = success && AIRail.BuildRail(station_data.depfront, station_data.stafront, station_data.frontfront);
success = success && AIRail.BuildRailDepot(station_data.deptile, station_data.depfront);
// if (AIController.GetSetting("signaltype") == 3) {
// // Build an extra path signal according to the setting
// success = success && AIRail.BuildSignal(station_data.stafront, station_data.depfront, AIRail.SIGNALTYPE_PBS);
// }
if (!success) {
// If we couldn't build the station for any reason
AILog.Warning("Station construction was interrupted.")
WormRailBuilder.RemoveRailLine(station_data.statile, rail_manager);
return false;
}
// Register the station
if (is_source) {
station_data.stasrc = AIStation.GetStationID(station_data.statile);
station_data.homedepot = station_data.deptile;
} else {
station_data.stadst = AIStation.GetStationID(station_data.statile);
}
return true;
}
function WormRailBuilder::CanBuildSingleRailStation(tile, direction, platform_length, station_data)
{
if (!AITile.IsBuildable(tile)) return false;
local vector, rvector = null;
// Determine some direction vectors
switch (direction) {
case DIR_NW:
vector = AIMap.GetTileIndex(0, -1);
rvector = AIMap.GetTileIndex(-1, 0);
station_data.stationdir = AIRail.RAILTRACK_NW_SE;
break;
case DIR_NE:
vector = AIMap.GetTileIndex(-1, 0);
rvector = AIMap.GetTileIndex(0, 1);
station_data.stationdir = AIRail.RAILTRACK_NE_SW;
break;
case DIR_SW:
vector = AIMap.GetTileIndex(1, 0);
rvector = AIMap.GetTileIndex(0, -1);
station_data.stationdir = AIRail.RAILTRACK_NE_SW;
break;
case DIR_SE:
vector = AIMap.GetTileIndex(0, 1);
rvector = AIMap.GetTileIndex(1, 0);
station_data.stationdir = AIRail.RAILTRACK_NW_SE;
break;
}
// Determine the top and the bottom tile of the station, used for building the station itself
if (direction == DIR_NW || direction == DIR_NE) {
station_data.stabottom = tile;
station_data.statop = tile + (platform_length-1) * vector;
station_data.statile = station_data.statop;
} else {
station_data.statop = tile;
station_data.stabottom = tile + (platform_length-1) * vector;
station_data.statile = station_data.stabottom;
}
// Set the other positions
station_data.depfront = station_data.statile + vector;
station_data.deptile = station_data.depfront + rvector;
station_data.stafront = station_data.depfront + vector;
station_data.frontfront = station_data.stafront + vector;
// Check if the station can be built
local test = AITestMode();
if (!AIRail.BuildRailStation(station_data.statop, station_data.stationdir, 1, platform_length,
AIStation.STATION_NEW)) return false;
if (!AIRail.BuildRailDepot(station_data.deptile, station_data.depfront)) return false;
if (!AITile.IsBuildable(station_data.depfront)) return false;
if (!AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.stafront)) return false;
if (!AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.deptile)) return false;
if (!AIRail.BuildRail(station_data.deptile, station_data.depfront, station_data.stafront)) return false;
if (!AITile.IsBuildable(station_data.stafront)) return false;
if (!AIRail.BuildRail(station_data.depfront, station_data.stafront, station_data.frontfront)) return false;
if (!AITile.IsBuildable(station_data.frontfront)) return false;
if (AITile.IsCoastTile(station_data.frontfront)) return false;
// Check if there is a station just at the back of the proposed station
if (AIRail.IsRailStationTile(station_data.statile - platform_length * vector)) {
if (AICompany.IsMine(AITile.GetOwner(station_data.statile - platform_length * vector)) &&
AIRail.GetRailStationDirection(station_data.statile - platform_length * vector) == station_data.stationdir)
return false;
}
test = null;
return true;
}
function WormRailBuilder::BuildRailStation(is_source, lanes, platform_length, route_data, station_data, rail_manager)
{
local dir, tilelist, otherplace, isneartown = null;
local rad = AIStation.GetCoverageRadius(AIStation.STATION_TRAIN);
// Determine the direction of the station, and get list of usable tiles.
if (is_source) {
// Source station
dir = WormTiles.GetDirection(route_data.SourceLocation, route_data.DestLocation);
station_data.optimaldir = dir; // Should only be set for source
if (route_data.SourceIsTown) {
// We don't need to use platform_length or width here because we only need part of
// our station to be inside town influence, not the whole station!
tilelist = WormRailBuilder.GetTilesAroundTown(route_data.SourceID, 1, 1);
isneartown = true;
} else {
tilelist = AITileList_IndustryProducing(route_data.SourceID, rad);
isneartown = false;
}
otherplace = route_data.DestLocation;
} else {
// Destination station
dir = WormTiles.GetDirection(route_data.DestLocation, route_data.SourceLocation);
if (route_data.DestIsTown) {
// We don't need to use platform_length or width here because we only need part of
// our station to be inside town influence, not the whole station!
tilelist = WormRailBuilder.GetTilesAroundTown(route_data.DestID, 1, 1);
isneartown = true;
} else {
tilelist = AITileList_IndustryAccepting(route_data.DestID, rad);
tilelist.Valuate(AITile.GetCargoAcceptance, route_data.Cargo, 1, 1, rad);
tilelist.RemoveBelowValue(8);
isneartown = false;
}
otherplace = route_data.SourceLocation;
}
// Only keep tiles where we can build.
tilelist.Valuate(AITile.IsBuildable);
tilelist.KeepValue(1);
// Sort the tile list to get the best candidate locations.
if (isneartown) {
tilelist.Valuate(AITile.GetCargoAcceptance, route_data.Cargo, 1, 1, rad);
tilelist.KeepAboveValue(10);
} else {
tilelist.Valuate(AIMap.DistanceManhattan, otherplace);
}
tilelist.Sort(AIList.SORT_BY_VALUE, !isneartown);
// Find a place where the station can be built
local success = false;
foreach (tile, dummy in tilelist) {
if (WormRailBuilder.CanBuildRailStation(tile, lanes, dir, platform_length, station_data)) {
success = true;
break;
} else continue;
}
if (!success) {
AILog.Info("Can't build station in optimal direction, trying next direction clockwise.");
local nextdir = WormTiles.GetNextDirection(dir, true);
// Find a place where the station can be built
foreach (tile, dummy in tilelist) {
if (WormRailBuilder.CanBuildRailStation(tile, lanes, nextdir, platform_length, station_data)) {
success = true;
break;
} else continue;
}
if (!success) {
AILog.Info("Still can't build station, trying counterclockwise direction.");
nextdir = WormTiles.GetNextDirection(dir, false);
// Find a place where the station can be built
foreach (tile, dummy in tilelist) {
if (WormRailBuilder.CanBuildRailStation(tile, lanes, nextdir, platform_length, station_data)) {
success = true;
break;
} else continue;
}
}
if (!success)
return false;
dir = nextdir;
//AILog.Info("[DEBUG] Good. We found a spot in this direction.");
}
// Build the station itself
// @todo The setting "newgrf_stations" was taken from SimpleAI and is currently not available
// as a setting in our AI so this if will currently always return false.
if (AIController.GetSetting("newgrf_stations") == 1 && !route_data.SourceIsTown && !route_data.DestIsTown) {
// Build a NewGRF rail station
success = success && AIRail.BuildNewGRFRailStation(station_data.statop, station_data.stationdir,
lanes, platform_length, AIStation.STATION_NEW, route_data.Cargo,
AIIndustry.GetIndustryType(route_data.SourceID), AIIndustry.GetIndustryType(route_data.DestID),
AIMap.DistanceManhattan(route_data.SourceLocation, route_data.DestLocation), is_source);
} else {
// Build a standard rail station
success = success && AIRail.BuildRailStation(station_data.statop, station_data.stationdir,
lanes, platform_length, AIStation.STATION_NEW);
}
if (!success) {
AILog.Error("Station could not be built: " + AIError.GetLastErrorString());
return false;
}
//AILog.Info("[DEBUG] Station was built, now build rail in front of it.");
// Build the station parts
if (lanes == 1) {
// 1 lane station
success = success && AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.stafront);
success = success && AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.deptile);
success = success && AIRail.BuildRail(station_data.deptile, station_data.depfront, station_data.stafront);
success = success && AIRail.BuildRail(station_data.depfront, station_data.stafront, station_data.frontfront);
}
else {
// 2 lane station
success = success && AIRail.BuildRail(station_data.statile, station_data.front1, station_data.depfront);
success = success && AIRail.BuildRail(station_data.lane2, station_data.front2, station_data.stafront);
success = success && AIRail.BuildRail(station_data.front1, station_data.depfront, station_data.deptile);
success = success && AIRail.BuildRail(station_data.front2, station_data.stafront, station_data.frontfront);
success = success && AIRail.BuildRail(station_data.front1, station_data.depfront, station_data.stafront);
success = success && AIRail.BuildRail(station_data.front2, station_data.stafront, station_data.depfront);
success = success && AIRail.BuildRail(station_data.depfront, station_data.stafront, station_data.frontfront);
success = success && AIRail.BuildRail(station_data.stafront, station_data.depfront, station_data.deptile);
success = success && AIRail.BuildRail(station_data.stafront, station_data.frontfront, station_data.morefront);
}
//if (success)
// AILog.Info("[DEBUG] Build depot.");
success = success && AIRail.BuildRailDepot(station_data.deptile, station_data.depfront);
if (success && (lanes > 1)) {
//AILog.Info("[DEBUG] Build signals.");
// local signaltype = (AIController.GetSetting("signaltype") >= 2) ? AIRail.SIGNALTYPE_PBS : AIRail.SIGNALTYPE_NORMAL_TWOWAY;
local signaltype = AIRail.SIGNALTYPE_PBS;
success = success && AIRail.BuildSignal(station_data.front1, station_data.statile, signaltype);
success = success && AIRail.BuildSignal(station_data.front2, station_data.lane2, signaltype);
}
if (!success) {
// Construction failed some reason
AILog.Warning("Station construction failed: " + AIError.GetLastErrorString());
WormRailBuilder.RemoveRailLine(station_data.statile, rail_manager);
if (lanes > 1)
WormRailBuilder.RemoveRailLine(station_data.front2, rail_manager);
return false;
}
// Register the station
if (is_source) {
station_data.stasrc = AIStation.GetStationID(station_data.statile);
station_data.homedepot = station_data.deptile;
} else {
station_data.stadst = AIStation.GetStationID(station_data.statile);
}
return true;
}
function WormRailBuilder::CanBuildRailStation(tile, lanes, direction, platform_length, station_data)
{
if (!AITile.IsBuildable(tile)) return false;
local vector, rvector = null;
// Set the direction vectors
switch (direction) {
case DIR_NW:
vector = AIMap.GetTileIndex(0, -1);
if (lanes > 1)
rvector = AIMap.GetTileIndex(1, 0); /// @todo Why is this different in CanBuildSingleRailStation?
else
rvector = AIMap.GetTileIndex(-1, 0);
station_data.stationdir = AIRail.RAILTRACK_NW_SE;
break;
case DIR_NE:
vector = AIMap.GetTileIndex(-1, 0);
rvector = AIMap.GetTileIndex(0, 1);
station_data.stationdir = AIRail.RAILTRACK_NE_SW;
break;
case DIR_SW:
vector = AIMap.GetTileIndex(1, 0);
if (lanes > 1)
rvector = AIMap.GetTileIndex(0, 1); /// @todo Why is this different in CanBuildSingleRailStation?
else
rvector = AIMap.GetTileIndex(0, -1);
station_data.stationdir = AIRail.RAILTRACK_NE_SW;
break;
case DIR_SE:
vector = AIMap.GetTileIndex(0, 1);
rvector = AIMap.GetTileIndex(1, 0);
station_data.stationdir = AIRail.RAILTRACK_NW_SE;
break;
}
// Determine the top and the bottom tile of the station, used for building the station itself
if (direction == DIR_NW || direction == DIR_NE) {
station_data.stabottom = tile;
station_data.statop = tile + (platform_length-1) * vector;
station_data.statile = station_data.statop;
} else {
station_data.statop = tile;
station_data.stabottom = tile + (platform_length-1) * vector;
station_data.statile = station_data.stabottom;
}
// Now turn on test mode to check if the station can be built.
local test = AITestMode();
// Set the tiles for the other station parts
/// @todo part of these can be merged, to be done after we know it's working
if (lanes > 1) {
station_data.lane2 = station_data.statile + rvector;
station_data.front1 = station_data.statile + vector;
station_data.front2 = station_data.lane2 + vector;
station_data.depfront = station_data.front1 + vector;
station_data.stafront = station_data.front2 + vector;
station_data.deptile = station_data.depfront + vector;
// Try the second option for the depot if the first one is not suitable
if (!AIRail.BuildRailDepot(station_data.deptile, station_data.depfront))
station_data.deptile = station_data.depfront - rvector;
station_data.frontfront = station_data.stafront + vector;
station_data.morefront = station_data.frontfront + vector;
// Try the second option for the station exit if the first one is not suitable
if ((!AITile.IsBuildable(station_data.frontfront)) || (!AITile.IsBuildable(station_data.morefront)) ||
(!AIRail.BuildRail(station_data.stafront, station_data.frontfront, station_data.morefront)) ||
(AITile.IsCoastTile(station_data.morefront))) {
station_data.frontfront = station_data.stafront + rvector;
station_data.morefront = station_data.frontfront + rvector;
}
}
else {
station_data.depfront = station_data.statile + vector;
station_data.deptile = station_data.depfront + rvector;
station_data.stafront = station_data.depfront + vector;
station_data.frontfront = station_data.stafront + vector;
}
// Do the tests
/// @todo generalize the different lanes so it will be easier to extend.
// Station and depot building
if (!AIRail.BuildRailStation(station_data.statop, station_data.stationdir, lanes, platform_length,
AIStation.STATION_NEW)) return false;
if (!AIRail.BuildRailDepot(station_data.deptile, station_data.depfront)) return false;
// rail building
if (lanes > 1) {
if (!AITile.IsBuildable(station_data.front1)) return false;
if (!AIRail.BuildRail(station_data.statile, station_data.front1, station_data.depfront)) return false;
if (!AITile.IsBuildable(station_data.front2)) return false;
if (!AIRail.BuildRail(station_data.lane2, station_data.front2, station_data.stafront)) return false;
if (!AITile.IsBuildable(station_data.depfront)) return false;
if (!AIRail.BuildRail(station_data.front1, station_data.depfront, station_data.deptile)) return false;
if (!AITile.IsBuildable(station_data.stafront)) return false;
if (!AIRail.BuildRail(station_data.front2, station_data.stafront, station_data.frontfront)) return false;
if (!AIRail.BuildRail(station_data.front1, station_data.depfront, station_data.stafront)) return false;
if (!AIRail.BuildRail(station_data.front2, station_data.stafront, station_data.depfront)) return false;
if (!AIRail.BuildRail(station_data.depfront, station_data.stafront, station_data.frontfront)) return false;
if (!AIRail.BuildRail(station_data.stafront, station_data.depfront, station_data.deptile)) return false;
if (!AITile.IsBuildable(station_data.frontfront)) return false;
if (!AITile.IsBuildable(station_data.morefront)) return false;
if (AITile.IsCoastTile(station_data.morefront)) return false;
if (!AIRail.BuildRail(station_data.stafront, station_data.frontfront, station_data.morefront)) return false;
}
else {
if (!AITile.IsBuildable(station_data.depfront)) return false;
if (!AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.stafront)) return false;
if (!AIRail.BuildRail(station_data.statile, station_data.depfront, station_data.deptile)) return false;
if (!AIRail.BuildRail(station_data.deptile, station_data.depfront, station_data.stafront)) return false;
if (!AITile.IsBuildable(station_data.stafront)) return false;
if (!AIRail.BuildRail(station_data.depfront, station_data.stafront, station_data.frontfront)) return false;
if (!AITile.IsBuildable(station_data.frontfront)) return false;
if (AITile.IsCoastTile(station_data.frontfront)) return false;
}
// Check if there is a station just at the back of the proposed station
if (AIRail.IsRailStationTile(station_data.statile - platform_length * vector)) {
if (AICompany.IsMine(AITile.GetOwner(station_data.statile - platform_length * vector)) &&
AIRail.GetRailStationDirection(station_data.statile - platform_length * vector) == station_data.stationdir)
return false;
}
if (lanes > 1) {
// Do the same for the second lane
if (AIRail.IsRailStationTile(station_data.lane2 - platform_length * vector)) {
if (AICompany.IsMine(AITile.GetOwner(station_data.lane2 - platform_length * vector)) &&
AIRail.GetRailStationDirection(station_data.lane2 - platform_length * vector) == station_data.stationdir)
return false;
}
}
// Testing done: building everything succeeded.
test = null;
return true;
}
function WormRailBuilder::BuildRail(head1, head2, railbridges)
{
local recursiondepth = 0;
return WormRailBuilder.InternalBuildRail(head1, head2, railbridges, recursiondepth);
}
function WormRailBuilder::InternalBuildRail(head1, head2, railbridges, recursiondepth)
{
local pathfinder = WormRailPathFinder();
// Set some pathfinder penalties
pathfinder._cost_level_crossing = 900;
if (AIGameSettings.GetValue("train_acceleration_model ") == 0) {
// Original
pathfinder._cost_slope = 500;
pathfinder._cost_turn = 50;
}
else {
// Realistic
// Slope steepness percentage: values 0-10 allowed.
pathfinder._cost_slope = 100 + AIGameSettings.GetValue("train_slope_steepness") * 50;
pathfinder._cost_turn = 150;
}
pathfinder._cost_coast = 100;
if (AIGameSettings.GetValue("forbid_90_deg"))
pathfinder._cost_90_turn = pathfinder._max_cost;
else
pathfinder._cost_90_turn = 250;
/// @todo Can we determine bridge/tunnel costs in advance here (e.g. expensive bridge newgrf)
/// Maybe also depend on railtype?
pathfinder._cost_bridge_per_tile = 150; //75;
pathfinder._cost_tunnel_per_tile = 75; //50;
// Limit bridge and tunnel length depending on how much money we have
local balance = AICompany.GetBankBalance(AICompany.COMPANY_SELF);
if (balance < WormMoney.InflationCorrection(100000)) {
pathfinder._max_bridge_length = 5;
pathfinder._max_tunnel_length = 5;
}
else if (balance < WormMoney.InflationCorrection(500000)) {
pathfinder._max_bridge_length = 10;
pathfinder._max_tunnel_length = 10;
}
else if (balance < WormMoney.InflationCorrection(1000000)) {
pathfinder._max_bridge_length = 15;
pathfinder._max_tunnel_length = 15;
}
else {
pathfinder._max_bridge_length = 20;
pathfinder._max_tunnel_length = 20;
}
// We don't want real short bridges since they can slow down trains.
pathfinder._min_bridge_length = 4;
pathfinder.InitializePath([head1], [head2]);
AILog.Info("Pathfinding...");
local counter = 0;
local path = false;
// Try to find a path
while (path == false && counter < 150) {
path = pathfinder.FindPath(150);
counter++;
AIController.Sleep(1);
}
if (path != null && path != false) {
AILog.Info("Path found. (" + counter + ")");
} else {
AILog.Warning("Pathfinding failed.");
return false;
}
local prev = null;
local prevprev = null;
local pp1, pp2, pp3 = null;
while (path != null) {
if (prevprev != null) {
if (AIMap.DistanceManhattan(prev, path.GetTile()) > 1) {
// If we are building a tunnel or a bridge
if (AITunnel.GetOtherTunnelEnd(prev) == path.GetTile()) {
// If we are building a tunnel
if (!AITunnel.BuildTunnel(AIVehicle.VT_RAIL, prev)) {
AILog.Warning("An error occured while I was building the rail: " + AIError.GetLastErrorString());
if (AIError.GetLastError() == AIError.ERR_NOT_ENOUGH_CASH) {
AILog.Warning("That tunnel would be too expensive. Construction aborted.");
return false;
}
// Try again if we have the money
if (!WormRailBuilder.RetryRail(prevprev, pp1, pp2, pp3, head1, railbridges, recursiondepth)) return false;
else return true;
}
} else {
// If we are building a bridge
/// @todo Maybe also valuate on price of the bridge and depend on the max speed we need maybe + a little extra for when we upgrade trains...
local bridgelen = AIMap.DistanceManhattan(path.GetTile(), prev) + 1;
local bridgelist = AIBridgeList_Length(bridgelen);
bridgelist.Valuate(AIBridge.GetMaxSpeed);
local _price = AIBridge.GetPrice(bridgelist.Begin(), bridgelen);
if (_price > 0.5*AICompany.GetBankBalance(AICompany.COMPANY_SELF)) {
AILog.Warning("Bridge is too expensive. Construction aborted.");
return false;
} else if (!AIBridge.BuildBridge(AIVehicle.VT_RAIL, bridgelist.Begin(), prev, path.GetTile())) {
AILog.Warning("An error occured while I was building the rail: " + AIError.GetLastErrorString());
if (AIError.GetLastError() == AIError.ERR_NOT_ENOUGH_CASH) {
AILog.Warning("That bridge would be too expensive. Construction aborted.");
return false;
}
// Try again if we have the money
if (!WormRailBuilder.RetryRail(prevprev, pp1, pp2, pp3, head1, railbridges, recursiondepth)) return false;
else return true;
} else {
// Register the new bridge
railbridges.AddTile(path.GetTile());
}
}
// Step these variables after a tunnel or bridge was built
pp3 = pp2;
pp2 = pp1;
pp1 = prevprev;
prevprev = prev;
prev = path.GetTile();
path = path.GetParent();
} else {
// If we are building a piece of rail track
if (!AIRail.BuildRail(prevprev, prev, path.GetTile())) {
AILog.Warning("An error occured while I was building the rail: " + AIError.GetLastErrorString());
// One of the possibilities I've seen that we maybe could handle differently: ERR_VEHICLE_IN_THE_WAY
// Also seen: ERR_OWNED_BY_ANOTHER_COMPANY
if (!WormRailBuilder.RetryRail(prevprev, pp1, pp2, pp3, head1, railbridges, recursiondepth)) return false;
else return true;
}
}
}
// Step these variables at the start of the construction
if (path != null) {
pp3 = pp2;
pp2 = pp1;
pp1 = prevprev;
prevprev = prev;