-
Notifications
You must be signed in to change notification settings - Fork 1
/
assembly.pas
275 lines (238 loc) · 5.44 KB
/
assembly.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
unit assembly;
{PASCAL- COMPILER : Assembly
Copyright (c) 1984 Per Brinch Hansen
Free pascal adaptation (c) Jari Korhonen, 2023}
interface
uses
Classes, SysUtils;
procedure Assemble;
implementation
uses defs, main, util;
const
MaxLabel = 1000;
type
Operations = set of OperationPart;
AssemblyTable = array [1..MaxLabel] of integer;
var
NoArguments, OneArgument, TwoArguments, {FourArguments,} Blocks, Jumps: Operations;
Op: OperationPart;
Arg1, Arg2, Arg3, Arg4: integer;
Address: integer;
Table: AssemblyTable;
procedure NextInstruction;
var
n: integer;
begin
n := utilReadInt();
Op := int2op(n);
if Op in NoArguments then { skip }
else if Op in OneArgument then
Arg1 := UtilReadInt()
else if Op in TwoArguments then
begin
Arg1 := UtilReadInt();
Arg2 := UtilReadInt();
end
else {Op in FourArguments}
begin
Arg1 := UtilReadInt();
Arg2 := UtilReadInt();
Arg3 := UtilReadInt();
Arg4 := UtilReadInt();
end;
end;
procedure Emit1(Op: Operationpart);
begin
Emit(Ord(Op));
//if Emitting then
// Writeln(Address, ': ', opsString(Op));
Address := Address + 1;
end;
procedure Emit2(Op: OperationPart; Arg: integer);
begin
Emit(Ord(Op));
Emit(Arg);
//if Emitting then
// Writeln(Address, ': ', opsString(Op), ' ', Arg);
Address := Address + 2;
end;
procedure Emit3(Op: OperationPart; Arg1, Arg2: integer);
begin
Emit(Ord(Op));
Emit(Arg1);
Emit(Arg2);
//if Emitting then
// Writeln(Address, ': ', opsString(Op), ' ', Arg1, ' ', Arg2);
Address := Address + 3;
end;
procedure Emit5(Op: OperationPart; Arg1, Arg2, Arg3, Arg4: integer);
begin
Emit(Ord(Op));
Emit(Arg1);
Emit(Arg2);
Emit(Arg3);
Emit(Arg4);
//if Emitting then
// Writeln(Address, ': ', opsString(Op), ' ', Arg1, ' ', Arg2, ' ', Arg3, ' ', Arg4);
Address := Address + 5;
end;
function Optimize(SpecialCase: boolean): boolean;
begin
Result := SpecialCase;
end;
function JumpDispl(LabelNo: integer): integer;
begin
Result := Table[LabelNo] - Address;
end;
procedure Assign(Length: integer);
begin
if Optimize(Length = 1) then
Emit1(SimpleAssign2)
else
Emit2(Assign2, Length);
NextInstruction;
end;
procedure Block(Op: OperationPart; VarLabel, TempLabel, BeginLabel, LineNo: integer);
begin
{Op in Operations[Procedure2, Program2 ]}
Emit5(Op, Table[VarLabel], Table[TempLabel],
JumpDispl(BeginLabel), LineNo);
NextInstruction;
end;
procedure DefAddr(LabelNo: integer);
begin
Table[LabelNo] := Address;
NextInstruction;
end;
procedure DefArg(LabelNo, Value: integer);
begin
Table[LabelNo] := Value;
NextInstruction;
end;
procedure Field(Displ: integer);
begin
if Optimize(Displ = 0) then { Empty }
else
Emit2(Field2, Displ);
NextInstruction;
end;
procedure Jump(Op: OperationPart; LabelNo: integer);
begin
{Op in Operations[Do2, Goto2]}
Emit2(Op, JumpDispl(LabelNo));
NextInstruction;
end;
procedure ProcCall(Level, LabelNo: integer);
var
Displ: integer;
begin
Displ := JumpDispl(LabelNo);
if Optimize(Level = 1) then
Emit2(GlobalCall2, Displ)
else
Emit3(ProcCall2, Level, Displ);
NextInstruction;
end;
procedure Value(Length: integer);
begin
if Optimize(Length = 1) then
Emit1(SimpleValue2)
else
Emit2(Value2, Length);
NextInstruction;
end;
procedure Variable(Level, Displ: integer);
begin
Nextinstruction;
while Optimize(Op = Field2) do
begin
Displ := Displ + Arg1;
NextInstruction;
end;
if Optimize(Level = 0) then
if (Op = Value2) and (Arg1 = 1) then
begin
Emit2(LocalValue2, Displ);
NextInstruction;
end
else
Emit2(LocalVar2, Displ)
else if Optimize(Level = 1) then
if (Op = Value2) and (Arg1 = 1) then
begin
Emit2(GlobalValue2, Displ);
NextInstruction;
end
else
Emit2(GlobalVar2, Displ)
else
Emit3(Variable2, Level, Displ);
end;
procedure CopyInstruction;
begin
if Op in NoArguments then
Emit1(Op)
else if Op in OneArgument then
Emit2(Op, Arg1)
else if Op in TwoArguments then
Emit3(Op, Arg1, Arg2)
else {Op in FourArguments}
Emit5(Op, Arg1, Arg2, Arg3, Arg4);
NextInstruction;
end;
procedure Assemble2;
begin
Address := 0;
NextInstruction;
while Op <> EndProg2 do
if Op = Assign2 then
Assign(Arg1)
else if Op in Blocks then
Block(Op, Arg1, Arg2, Arg3, Arg4)
else if Op = DefAddr2 then
DefAddr(Arg1)
else if Op = DefArg2 then
DefArg(Arg1, Arg2)
else if Op = Field2 then
Field(Arg1)
else if Op in Jumps then
Jump(Op, Arg1)
else if Op = ProcCall2 then
ProcCall(Arg1, Arg2)
else if Op = Value2 then
Value(Arg1)
else if Op = Variable2 then
Variable(Arg1, Arg2)
else
CopyInstruction;
Emit1(EndProg2);
end;
procedure Initialize;
var
LabelNo: integer;
begin
NoArguments := [Add2, And2, Divide2, EndProg2, Equal2, Greater2,
Less2, Minus2, Modulo2, Multiply2, Not2, NotEqual2, NotGreater2,
NotLess2, Or2, Subtract2, Read2, Write2];
OneArgument := [Assign2, Constant2, Do2, EndProc2, Field2, Goto2, Value2, DefAddr2];
TwoArguments := [ProcCall2, Variable2, VarParam2, DefArg2];
//FourArguments := [Index2, Procedure2, Program2];
Blocks := [Procedure2, Program2];
Jumps := [Do2, Goto2];
LabelNo := 1;
while LabelNo <= MaxLabel do
begin
Table[LabelNo] := 0;
LabelNo := labelNo + 1;
end;
InitPass(PASS3_ASSEMBLE);
end;
procedure Assemble;
begin
Initialize;
Assemble2;
Rerun;
Assemble2;
//DbgOutputPass3();
end;
end.