-
Notifications
You must be signed in to change notification settings - Fork 2
/
build.gradle
318 lines (279 loc) · 9.04 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
import org.gradle.internal.os.OperatingSystem
/**
* Gradle plugins
*/
plugins {
id 'com.github.johnrengelman.shadow' version '8.1.1'
id 'java'
}
/**
* Project Variables
*/
group = 'com.avrix'
version = '1.6.0'
/**
* Path to the compiled Jar file
*/
def buildPath = System.getenv('BUILD_PATH') ?: 'build';
def baseArchiveName = "${rootProject.name.capitalize()}-Core";
/**
* Repositories for project dependencies
*/
repositories {
mavenCentral()
flatDir {
dirs project.file("$rootProject.projectDir/libs")
}
}
/**
* LWJGL switch natives
*/
switch (OperatingSystem.current()) {
case OperatingSystem.LINUX:
project.ext.lwjglNatives = "natives-linux"
def osArch = System.getProperty("os.arch")
if (osArch.startsWith("arm") || osArch.startsWith("aarch64")) {
project.ext.lwjglNatives += osArch.contains("64") || osArch.startsWith("armv8") ? "-arm64" : "-arm32"
} else if (osArch.startsWith("ppc")) {
project.ext.lwjglNatives += "-ppc64le"
} else if (osArch.startsWith("riscv")) {
project.ext.lwjglNatives += "-riscv64"
}
break
case OperatingSystem.MAC_OS:
project.ext.lwjglNatives = "natives-macos"
break
case OperatingSystem.WINDOWS:
def osArch = System.getProperty("os.arch")
project.ext.lwjglNatives = osArch.contains("64")
? "natives-windows${osArch.startsWith("aarch64") ? "-arm64" : ""}"
: "natives-windows-x86"
break
}
/**
* Project Dependencies
*/
dependencies {
/**
* Project Zomboid
* Dependencies are created via the Gradle task 'createZombieJar'
*/
compileOnly files('libs/ProjectZomboid-core-41.78.16.jar')
compileOnly files('libs/ProjectZomboid-libs-41.78.16.jar')
/**
* Utils
*/
implementation('org.yaml:snakeyaml:2.2')
implementation('org.javassist:javassist:3.30.2-GA')
implementation('org.tinylog:tinylog-api:2.7.0')
implementation('org.tinylog:tinylog-impl:2.7.0')
implementation 'org.json:json:20240303'
testImplementation 'org.json:json:20240303'
implementation platform("org.lwjgl:lwjgl-bom:3.3.4")
implementation "org.lwjgl:lwjgl-nanovg"
runtimeOnly "org.lwjgl:lwjgl::$lwjglNatives"
runtimeOnly "org.lwjgl:lwjgl-nanovg::$lwjglNatives"
/**
* Test
*/
testImplementation platform('org.junit:junit-bom:5.10.0')
testImplementation('org.junit.jupiter:junit-jupiter')
}
/**
* Project testing
*/
test {
dependsOn shadowJar
classpath = project.sourceSets.test.output + configurations.testRuntimeClasspath + files("${buildPath}/${rootProject.name}-Core-${version}.jar")
jvmArgs '-Djdk.attach.allowAttachSelf=true'
useJUnitPlatform()
}
/**
* Configures the source sets for the project.
*/
sourceSets {
main {
resources {
srcDir 'src/main/resources'
}
}
test {
resources {
srcDir 'src/test/resources'
}
}
}
/**
* Configures the processTestResources task to handle duplicate resources.
*/
processTestResources {
duplicatesStrategy = DuplicatesStrategy.INCLUDE
}
/**
* Replacing data with current ones
*/
processResources {
duplicatesStrategy = DuplicatesStrategy.INCLUDE
filesMatching('**/avrix.properties') {
filter {
it.replace('%PROJECT_VERSION%', version)
.replace('%PROJECT_NAME%', rootProject.name.capitalize() + " Loader")
}
}
}
/**
* Creating a Jar file wrapper (core) to run a game server
*/
shadowJar {
archiveBaseName.set(baseArchiveName)
archiveClassifier.set('')
destinationDirectory.set(file(buildPath))
manifest {
attributes(
'Implementation-Title': rootProject.name.capitalize(),
'Implementation-Version': version,
'Agent-Class': 'com.avrix.agent.Agent',
'Can-Redefine-Classes': 'true',
'Can-Retransform-Classes': 'true'
)
}
}
/**
* Building a release Jars archive with documentation and sources
*/
tasks.register('releaseBuildJar') {
dependsOn javadocJar, sourceJar
finalizedBy buildJar
}
/**
* Building a Jar archive with documentation
*/
tasks.register('buildJar') {
finalizedBy shadowJar
}
/**
* Creating javadoc in jar archive
*/
tasks.register('javadocJar', Jar) {
dependsOn(tasks.generateJavaDoc)
archiveBaseName.set(baseArchiveName)
archiveClassifier.set('javadoc')
from(file("docs/javadoc"))
destinationDirectory.set(file(buildPath))
}
/**
* Packaging source code in a Jar archive
*/
tasks.register('sourceJar', Jar) {
duplicatesStrategy = DuplicatesStrategy.EXCLUDE
archiveBaseName.set(baseArchiveName)
archiveClassifier.set('sources')
from(sourceSets.main.allSource)
destinationDirectory.set(file(buildPath))
}
/**
* Generating Jar Files of Project Zomboid File Dependencies
* Required environment variables:
* 1) ZOMBIE_FOLDER_PATH (For example: C:\Steam\steamapps\common\Project Zomboid Dedicated Server\java\zombie)
* 2) GAME_FOLDER_PATH (For example: C:\Steam\steamapps\common\Project Zomboid Dedicated Server\java)
*/
tasks.register('buildZomboidDependencies') {
dependsOn createZombieLibsJar, createZombieJar
}
/**
* Generating JavaDoc for Jar archive
*/
tasks.register('generateJavaDoc', Javadoc) {
source = sourceSets.main.allJava
classpath = sourceSets.main.compileClasspath
destinationDir = file("docs/javadoc")
options {
encoding = 'UTF-8'
charSet = 'UTF-8'
links("https://docs.oracle.com/en/java/javase/17/docs/api/")
memberLevel = JavadocMemberLevel.PUBLIC
}
}
/**
* Task for creating a JAR file named 'ProjectZomboid-core-41.78.16.jar' from the contents of a specified folder.
* For example ZOMBIE_FOLDER_PATH: C:\Steam\steamapps\common\Project Zomboid Dedicated Server\java\zombie
*/
tasks.register('createZombieJar') {
doLast {
def zombieFolderPath = System.getenv("ZOMBIE_FOLDER_PATH")
def archiveName = 'ProjectZomboid-core-41.78.16.jar'
if (zombieFolderPath != null && !zombieFolderPath.isEmpty()) {
def tempDir = file('tempDir')
def tempDirZombie = file('tempDir/zombie')
tempDir.mkdirs()
copy {
from zombieFolderPath
into tempDirZombie
}
exec {
commandLine 'jar', 'cvf', archiveName, '-C', tempDir, '.'
}
def libsFolder = file('libs')
libsFolder.mkdirs()
def targetFile = file("${libsFolder}/${archiveName}")
if (targetFile.exists()) {
targetFile.delete()
}
file(archiveName).renameTo(targetFile)
delete tempDir
} else {
println "The ZOMBIE_FOLDER_PATH environment variable is not set or is empty."
}
}
}
/**
* Task for creating a JAR file named 'ProjectZomboid-libs-41.78.16.jar' from the contents of a specified folder.
* For example GAME_FOLDER_PATH: C:\Steam\steamapps\common\Project Zomboid Dedicated Server\java
*/
tasks.register('createZombieLibsJar') {
doLast {
def gameFolderPath = System.getenv('GAME_FOLDER_PATH')
def archiveName = 'ProjectZomboid-libs-41.78.16.jar'
if (gameFolderPath != null && !gameFolderPath.isEmpty()) {
def tempDir = file('temps')
tempDir.mkdirs()
def jarFiles = file(gameFolderPath).listFiles().findAll { it.isFile() && it.name.endsWith('.jar') && !it.name.contains(rootProject.name) }
def excludedFolders = ['zombie', 'jre', 'jre64', 'launcher', 'media',
'license', 'mods', 'win32', 'win64', 'workshop']
def includedFolders = file(gameFolderPath).listFiles().findAll { it.isDirectory() && !excludedFolders.contains(it.name.toLowerCase()) }
includedFolders.each { dir ->
copy {
from dir
into file("${tempDir}/${dir.name}")
}
}
jarFiles.each { jarFile ->
copy {
from jarFile
into tempDir
}
}
def tempJarFiles = tempDir.listFiles().findAll { it.isFile() && it.name.endsWith('.jar') }
tempJarFiles.each { jarFile ->
exec {
workingDir tempDir
commandLine 'jar', 'xf', jarFile.absolutePath
}
jarFile.delete()
}
exec {
commandLine 'jar', 'cvf', archiveName, '-C', tempDir, '.'
}
def libsFolder = file('libs')
libsFolder.mkdirs()
def targetFile = file("${libsFolder}/${archiveName}")
if (targetFile.exists()) {
targetFile.delete()
}
file(archiveName).renameTo(file("${libsFolder}/${archiveName}"))
delete tempDir
} else {
println('The GAME_FOLDER_PATH environment variable is not set or is empty.')
}
}
}